kc3-lang/automake/m4/missing.m4

Tag - branch -masterv1.18- tag -v1.18.1v1.17.92v1.17.90v1.17v1.16iv1.16.92v1.16.90v1.16.5v1.16.4v1.16.3v1.16.2v1.16.1v1.16v1.15.1v1.15v1.14.1v1.14v1.13bv1.13.4v1.13.3v1.13.2bv1.13.2v1.13.1dv1.13.1bv1.13.1v1.13v1.12bv1.12.6v1.12.5v1.12.4v1.12.3v1.12.2v1.12.1v1.12.0bv1.12v1.11dv1.11bv1.11v1.10buser-dep-gen-branchpointpre-ian-conditionalspre-depend-changeng-0.5amerging-into-user-dep-genlast-merge-into-user-dep-gen-branchhandle-languagesbranchpoint-real-1-5branchpoint-1-9branchpoint-1-8branchpoint-1-7branchpoint-1-6branchpoint-1-5branchpoint-1-10Release-1-9bRelease-1-9Release-1-8dRelease-1-8bRelease-1-8Release-1-7hRelease-1-7fRelease-1-7dRelease-1-7bRelease-1-7-3bRelease-1-7-2bRelease-1-7Release-1-6fRelease-1-6dRelease-1-6bRelease-1-6-1bRelease-1-6Release-1-5dRelease-1-5bRelease-1-4jRelease-1-4hRelease-1-4fRelease-1-4dRelease-1-4bRelease-1-4Release-1-3dRelease-1-3bRelease-1-3Release-1-2hRelease-1-2gRelease-1-2eRelease-1-2dRelease-1-2cRelease-1-2bRelease-1-2Release-1-1pRelease-1-1oRelease-1-1mRelease-1-1lRelease-1-1kRelease-1-1iRelease-1-1hRelease-1-1gRelease-1-1fRelease-1-1eRelease-1-1dRelease-1-1cRelease-1-1bRelease-1-1aRelease-1-10Release-1-0Release-0-33Release-0-32Release-0-31Release-0-30Release-0-29Release-0-28Release-0-27Release-0-26Release-0-25

• Show log

  Commit

• Hash : 1e2c6b41
  Author :
  Date : 2001-01-16T11:04:36
  

  * m4/multi.m4: Remove the hairy useless quotation of `$'.
  Simplify `ifelse([$2],,,[$2])' into... `$2'!
  * m4/minuso.m4: Don't use changequote!
  * m4/cond.m4: Fix quotation.
  * m4/sanity.m4: Follow the Autoconf coding style.
  * m4/missing.m4 (AM_MISSING_INSTALL_SH): Use a for loop.
  * m4/depend.m4 (AM_DEPENDENCIES): Fix quotation issues.
  Use AC_CACHE_CHECK.
  

Download

• m4/missing.m4

• ## --------------------------------------------------------- ##
  ## Fake the existence of programs that GNU maintainers use.  ##
  ## --------------------------------------------------------- ##
  
  # serial 2
  
  # AM_MISSING_PROG(NAME, PROGRAM)
  # ------------------------------
  AC_DEFUN([AM_MISSING_PROG],
  [AC_REQUIRE([AM_MISSING_HAS_RUN])
  $1=${$1-"${am_missing_run}$2"}
  AC_SUBST($1)])
  
  
  # AM_MISSING_INSTALL_SH
  # ---------------------
  # Like AM_MISSING_PROG, but only looks for install-sh.
  AC_DEFUN([AM_MISSING_INSTALL_SH],
  [AC_REQUIRE([AM_MISSING_HAS_RUN])
  if test -z "$install_sh"; then
     for install_sh in "$ac_aux_dir/install-sh" \
                       "$ac_aux_dir/install.sh" \
                       "${am_missing_run}${ac_auxdir}/install-sh";
     do
       test -f "$install_sh" && break
     done
     # FIXME: an evil hack: we remove the SHELL invocation from
     # install_sh because automake adds it back in.  Sigh.
     install_sh=`echo $install_sh | sed -e 's/\${SHELL}//'`
  fi
  AC_SUBST(install_sh)])
  
  
  # AM_MISSING_HAS_RUN
  # ------------------
  # Define MISSING if not defined so far and test if it supports --run.
  # If it does, set am_missing_run to use it, otherwise, to nothing.
  AC_DEFUN([AM_MISSING_HAS_RUN],
  [test x"${MISSING+set}" = xset ||
    MISSING="\${SHELL} `CDPATH=:; cd $ac_aux_dir && pwd`/missing"
  # Use eval to expand $SHELL
  if eval "$MISSING --run :"; then
    am_missing_run="$MISSING --run "
  else
    am_missing_run=
    am_backtick='`'
    AC_MSG_WARN([${am_backtick}missing' script is too old or missing])
  fi
  ])
  

Download