kc3-lang/automake/m4/multi.m4

• Show log

  Commit

• Hash : da2d6085
  Author :
  Date : 2000-08-26T20:52:57
  

  2000-04-14  Victor V. Vengerov <vvv@oktet.ru>
  
  	Fix for PR automake/67.
  	* automake.in (handle_multilib): remove .am suffix in fragment
  	name passed to file_contents.
  	* m4/multi.m4: Add missing ')' in AC_ARG_ENABLE invocation.
  	Remove external quotes in first arg of AC_OUTPUT_COMMANDS.
  	Remove unnecessary "rel-to-top-srcdir" before config-ml.in.
  

Download

• m4/multi.m4

• # Add --enable-multilib to configure.
  # Usage: AM_ENABLE_MULTILIB([makefile, [rel-to-top-srcdir]])
  
  AC_DEFUN([AM_ENABLE_MULTILIB], [
  # Default to --enable-multilib
  AC_ARG_ENABLE(multilib,
  [  --enable-multilib         build many library versions (default)],
  [case "${enableval}" in
    yes) multilib=yes ;;
    no)  multilib=no ;;
    *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
   esac], [multilib=yes])
  
  # We may get other options which we are undocumented:
  # --with-target-subdir, --with-multisrctop, --with-multisubdir
  
  if test "[$]{srcdir}" = "."; then
    if test "[$]{with_target_subdir}" != "."; then
      multi_basedir="[$]{srcdir}/[$]{with_multisrctop}../ifelse([$2],,,[$2])"
    else
      multi_basedir="[$]{srcdir}/[$]{with_multisrctop}ifelse([$2],,,[$2])"
    fi
  else
    multi_basedir="[$]{srcdir}/ifelse([$2],,,[$2])"
  fi
  AC_SUBST(multi_basedir)
  
  AC_OUTPUT_COMMANDS(
  if test -n "$CONFIG_FILES"; then
     ac_file=[]ifelse([$1],,Makefile,[$1]) . ${multi_basedir}/config-ml.in
  fi, [
  srcdir="$srcdir"
  host="$host"
  target="$target"
  with_multisubdir="$with_multisubdir"
  with_multisrctop="$with_multisrctop"
  with_target_subdir="$with_target_subdir"
  ac_configure_args="${multilib_arg} ${ac_configure_args}"
  multi_basedir="$multi_basedir"
  CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
  CC="$CC"])])dnl
  

Download