kc3-lang/automake/m4/vala.m4

• Show log

  Commit

• Hash : f8f22fea
  Author :
  Date : 2012-02-23T19:36:20
  

  m4: do not quote `like this', as per GCS recommendation
  
  This patch converts the files comprising the automake's own build
  system to the use of new quoting format 'like this' or "like this"
  rather than `like this'.
  
  * m4/auxdir.m4, m4/ccstdc.m4, m4/depend.m4, m4/depout.m4, m4/tar.m4,
  m4/init.m4, m4/maintainer.m4, m4/make.m4, m4/missing.m4, m4/vala.m4,
  m4/mkdirp.m4, m4/sanity.m4, m4/silent.m4, m4/strip.m4: Update and
  adjust quoting format throughout, in comments and diagnostic.  Some
  minor related rewordings and reformatting since we are at it.  Bump
  serial numbers.
  

Download

• m4/vala.m4

• # Autoconf support for the Vala compiler
  
  # Copyright (C) 2008-2012 Free Software Foundation, Inc.
  #
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  # serial 5
  
  # Check whether the Vala compiler exists in $PATH. If it is found, the
  # variable VALAC is set. Optionally a minimum release number of the
  # compiler can be requested.
  #
  # AM_PROG_VALAC([MINIMUM-VERSION])
  # --------------------------------
  AC_DEFUN([AM_PROG_VALAC],
  [AC_PATH_PROG([VALAC], [valac], [])
   AS_IF([test -z "$VALAC"],
     [AC_MSG_WARN([No Vala compiler found.  You will not be able to compile .vala source files.])],
     [AS_IF([test -n "$1"],
        [AC_MSG_CHECKING([$VALAC is at least version $1])
         am__vala_version=`$VALAC --version | sed 's/Vala  *//'`
         AS_VERSION_COMPARE([$1], ["$am__vala_version"],
           [AC_MSG_RESULT([yes])],
           [AC_MSG_RESULT([yes])],
           [AC_MSG_RESULT([no])
            AC_MSG_ERROR([Vala $1 not found.])])])])
  ])
  

Download