depout.m4

Branch :

Show log
Commit
Author : Akim Demaille
Date : 2003-06-02 07:08:40
Hash : f68696e2
Message : * lib/am/texi-vers.am, lib/am/subdirs.am, lib/am/scripts.am, * lib/am/remake-hdr.am, lib/am/python.am, lib/am/progs.am, * lib/am/program.am, lib/am/multilib.am, lib/am/mans.am, * lib/am/mans-vars.am, lib/am/ltlibrary.am, lib/am/ltlib.am, * lib/am/lisp.am, lib/am/libtool.am, lib/am/library.am, * lib/am/lang-compile.am, lib/am/java.am, lib/am/header.am, * lib/am/header-vars.am, lib/am/footer.am, lib/am/depend.am, * lib/am/dejagnu.am, lib/am/data.am, lib/am/compile.am, * lib/am/clean.am, lib/am/clean-hdr.am, lib/am/check.am, * lib/am/ansi2knr.am, lib/am/Makefile.am, lib/Makefile.am, * m4/strip.m4, m4/sanity.m4, m4/runlog.m4, m4/regex.m4, * m4/python.m4, m4/protos.m4, m4/options.m4, m4/obsolete.m4, * m4/obsol-lt.m4, m4/obsol-gt.m4, m4/multi.m4, m4/missing.m4, * m4/minuso.m4, m4/maintainer.m4, m4/lispdir.m4, m4/lex.m4, * m4/install-sh.m4, m4/header.m4, m4/gcj.m4, m4/dmalloc.m4, * m4/depout.m4, m4/cond.m4, m4/ccstdc.m4, m4/auxdir.m4, m4/as.m4, * m4/Makefile.am: White space changes and Copyright updates.

m4/depout.m4

# Generate code to set up dependency tracking.   -*- Autoconf -*-

# Copyright (C) 1999, 2000, 2001, 2002, 2003 Free Software Foundation, Inc.

# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2, or (at your option)
# any later version.

# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.

# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
# 02111-1307, USA.

#serial 2

# _AM_OUTPUT_DEPENDENCY_COMMANDS
# ------------------------------
AC_DEFUN([_AM_OUTPUT_DEPENDENCY_COMMANDS],
[for mf in $CONFIG_FILES; do
  # Strip MF so we end up with the name of the file.
  mf=`echo "$mf" | sed -e 's/:.*$//'`
  # Check whether this is an Automake generated Makefile or not.
  # We used to match only the files named `Makefile.in', but
  # some people rename them; so instead we look at the file content.
  # Grep'ing the first line is not enough: some people post-process
  # each Makefile.in and add a new line on top of each file to say so.
  # So let's grep whole file.
  if grep '^#.*generated by automake' $mf > /dev/null 2>&1; then
    dirpart=`AS_DIRNAME("$mf")`
  else
    continue
  fi
  grep '^DEP_FILES *= *[[^ @%:@]]' < "$mf" > /dev/null || continue
  # Extract the definition of DEP_FILES from the Makefile without
  # running `make'.
  DEPDIR=`sed -n -e '/^DEPDIR = / s///p' < "$mf"`
  test -z "$DEPDIR" && continue
  # When using ansi2knr, U may be empty or an underscore; expand it
  U=`sed -n -e '/^U = / s///p' < "$mf"`
  test -d "$dirpart/$DEPDIR" || mkdir "$dirpart/$DEPDIR"
  # We invoke sed twice because it is the simplest approach to
  # changing $(DEPDIR) to its actual value in the expansion.
  for file in `sed -n -e '
    /^DEP_FILES = .*\\\\$/ {
      s/^DEP_FILES = //
      :loop
	s/\\\\$//
	p
	n
	/\\\\$/ b loop
      p
    }
    /^DEP_FILES = / s/^DEP_FILES = //p' < "$mf" | \
       sed -e 's/\$(DEPDIR)/'"$DEPDIR"'/g' -e 's/\$U/'"$U"'/g'`; do
    # Make sure the directory exists.
    test -f "$dirpart/$file" && continue
    fdir=`AS_DIRNAME(["$file"])`
    AS_MKDIR_P([$dirpart/$fdir])
    # echo "creating $dirpart/$file"
    echo '# dummy' > "$dirpart/$file"
  done
done
])# _AM_OUTPUT_DEPENDENCY_COMMANDS


# AM_OUTPUT_DEPENDENCY_COMMANDS
# -----------------------------
# This macro should only be invoked once -- use via AC_REQUIRE.
#
# This code is only required when automatic dependency tracking
# is enabled.  FIXME.  This creates each `.P' file that we will
# need in order to bootstrap the dependency handling code.
AC_DEFUN([AM_OUTPUT_DEPENDENCY_COMMANDS],
[AC_CONFIG_COMMANDS([depfiles],
     [test x"$AMDEP_TRUE" != x"" || _AM_OUTPUT_DEPENDENCY_COMMANDS],
     [AMDEP_TRUE="$AMDEP_TRUE" ac_aux_dir="$ac_aux_dir"])
])

kc3-lang/automake/m4/depout.m4

Commit

kc3-lang/automake /m4/depout.m4