regex.m4

Branch :

Show log
Commit
Author : Alexandre Duret-Lutz
Date : 2005-01-09 14:46:22
Hash : 391df12b
Message : * m4/amversion.in, m4/as.m4, m4/auxdir.m4, m4/ccstdc.m4, m4/cond.m4, m4/depend.m4, m4/depout.m4, m4/dmalloc.m4, m4/gcj.m4, m4/header.m4, m4/init.m4, m4/install-sh.m4, m4/lead-dot.m4, m4/lex.m4, m4/lispdir.m4, m4/maintainer.m4, m4/make.m4, m4/minuso.m4, m4/missing.m4, m4/mkdirp.m4, m4/multi.m4, m4/obsol-gt.m4, m4/obsol-lt.m4, m4/obsolete.m4, m4/options.m4, m4/protos.m4, m4/python.m4, m4/regex.m4, m4/runlog.m4, m4/sanity.m4, m4/strip.m4, m4/tar.m4: Use the same all-permissive license that is used in aclocal.m4. Relicensing backed by RMS.

m4/regex.m4

## --------------------------------- ##                     -*- Autoconf -*-
## Check if --with-regex was given.  ##
## --------------------------------- ##
# Copyright (C) 1996, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005
# Free Software Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.

# serial 7

# AM_WITH_REGEX
# -------------
#
# The idea is to distribute rx.[hc] and regex.[hc] together, for a
# while.  The WITH_REGEX symbol is used to decide which of regex.h or
# rx.h should be included in the application.  If `./configure
# --with-regex' is given (the default), the package will use gawk's
# regex.  If `./configure --without-regex', a check is made to see if
# rx is already installed, as with newer Linux'es.  If not found, the
# package will use the rx from the distribution.  If found, the
# package will use the system's rx which, on Linux at least, will
# result in a smaller executable file.
#
# FIXME: This macro seems quite obsolete now since rx doesn't seem to
# be maintained, while regex is.
AC_DEFUN([AM_WITH_REGEX],
[AC_PREREQ(2.50)dnl
AC_LIBSOURCES([rx.h, rx.c, regex.c, regex.h])dnl
AC_MSG_CHECKING([which of GNU rx or gawk's regex is wanted])
AC_ARG_WITH([regex],
[  --without-regex         use GNU rx in lieu of gawk's regex for matching],
	    [test "$withval" = yes && am_with_regex=1],
	    [am_with_regex=1])
if test -n "$am_with_regex"; then
  AC_MSG_RESULT([regex])
  AC_DEFINE([WITH_REGEX], 1, [Define if using GNU regex])
  AC_CACHE_CHECK([for GNU regex in libc], [am_cv_gnu_regex],
    [AC_TRY_LINK([],
		 [extern int re_max_failures; re_max_failures = 1],
		 [am_cv_gnu_regex=yes],
		 [am_cv_gnu_regex=no])])
  if test $am_cv_gnu_regex = no; then
    AC_LIBOBJ([regex])
  fi
else
  AC_MSG_RESULT([rx])
  AC_CHECK_FUNC([re_rx_search], , [AC_LIBOBJ([rx])])
fi[]dnl
])

AU_DEFUN([fp_WITH_REGEX], [AM_WITH_REGEX])

kc3-lang/automake/m4/regex.m4

Commit

kc3-lang/automake /m4/regex.m4