sanity.m4

Branch :

Show log
Commit
Author : Alexandre Duret-Lutz
Date : 2005-01-09 14:46:22
Hash : 391df12b
Message : * m4/amversion.in, m4/as.m4, m4/auxdir.m4, m4/ccstdc.m4, m4/cond.m4, m4/depend.m4, m4/depout.m4, m4/dmalloc.m4, m4/gcj.m4, m4/header.m4, m4/init.m4, m4/install-sh.m4, m4/lead-dot.m4, m4/lex.m4, m4/lispdir.m4, m4/maintainer.m4, m4/make.m4, m4/minuso.m4, m4/missing.m4, m4/mkdirp.m4, m4/multi.m4, m4/obsol-gt.m4, m4/obsol-lt.m4, m4/obsolete.m4, m4/options.m4, m4/protos.m4, m4/python.m4, m4/regex.m4, m4/runlog.m4, m4/sanity.m4, m4/strip.m4, m4/tar.m4: Use the same all-permissive license that is used in aclocal.m4. Relicensing backed by RMS.

m4/sanity.m4

# Check to make sure that the build environment is sane.    -*- Autoconf -*-

# Copyright (C) 1996, 1997, 2000, 2001, 2003, 2005
# Free Software Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.

# serial 4

# AM_SANITY_CHECK
# ---------------
AC_DEFUN([AM_SANITY_CHECK],
[AC_MSG_CHECKING([whether build environment is sane])
# Just in case
sleep 1
echo timestamp > conftest.file
# Do `set' in a subshell so we don't clobber the current shell's
# arguments.  Must try -L first in case configure is actually a
# symlink; some systems play weird games with the mod time of symlinks
# (eg FreeBSD returns the mod time of the symlink's containing
# directory).
if (
   set X `ls -Lt $srcdir/configure conftest.file 2> /dev/null`
   if test "$[*]" = "X"; then
      # -L didn't work.
      set X `ls -t $srcdir/configure conftest.file`
   fi
   rm -f conftest.file
   if test "$[*]" != "X $srcdir/configure conftest.file" \
      && test "$[*]" != "X conftest.file $srcdir/configure"; then

      # If neither matched, then we have a broken ls.  This can happen
      # if, for instance, CONFIG_SHELL is bash and it inherits a
      # broken ls alias from the environment.  This has actually
      # happened.  Such a system could not be considered "sane".
      AC_MSG_ERROR([ls -t appears to fail.  Make sure there is not a broken
alias in your environment])
   fi

   test "$[2]" = conftest.file
   )
then
   # Ok.
   :
else
   AC_MSG_ERROR([newly created file is older than distributed files!
Check your system clock])
fi
AC_MSG_RESULT(yes)])

kc3-lang/automake/m4/sanity.m4

Commit

kc3-lang/automake /m4/sanity.m4