strip.m4

Branch :

Show log
Commit
Author : Alexandre Duret-Lutz
Date : 2005-10-03 20:48:59
Hash : 9bd67a2f
Message : 2005-10-03 Alexandre Duret-Lutz <adl@gnu.org> * tests/nobase.test: Exercise previous patch. 2005-10-03 Peter O'Gorman <peter@pogma.com> (tiny change) * lib/am/distdir.am: Remove $(SHELL) when calling install_sh * m4/strip.m4: Ditto. * m4/install-sh.m4: Add $(SHELL) to the definition of install_sh

m4/strip.m4

##                                                          -*- Autoconf -*-
# Copyright (C) 2001, 2003, 2005  Free Software Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.

# AM_PROG_INSTALL_STRIP
# ---------------------
# One issue with vendor `install' (even GNU) is that you can't
# specify the program used to strip binaries.  This is especially
# annoying in cross-compiling environments, where the build's strip
# is unlikely to handle the host's binaries.
# Fortunately install-sh will honor a STRIPPROG variable, so we
# always use install-sh in `make install-strip', and initialize
# STRIPPROG with the value of the STRIP variable (set by the user).
AC_DEFUN([AM_PROG_INSTALL_STRIP],
[AC_REQUIRE([AM_PROG_INSTALL_SH])dnl
# Installed binaries are usually stripped using `strip' when the user
# run `make install-strip'.  However `strip' might not be the right
# tool to use in cross-compilation environments, therefore Automake
# will honor the `STRIP' environment variable to overrule this program.
dnl Don't test for $cross_compiling = yes, because it might be `maybe'.
if test "$cross_compiling" != no; then
  AC_CHECK_TOOL([STRIP], [strip], :)
fi
INSTALL_STRIP_PROGRAM="\$(install_sh) -c -s"
AC_SUBST([INSTALL_STRIP_PROGRAM])])

kc3-lang/automake/m4/strip.m4

Commit

kc3-lang/automake /m4/strip.m4