init.m4

Branch :

Show log
Commit
Author : Tom Tromey
Date : 1998-10-09 11:10:23
Hash : a150fe6f
Message : * m4/winsz.m4 (AM_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL): Use 3-argument form of AC_DEFINE. * m4/regex.m4 (AM_WITH_REGEX): Use 3-argument form of AC_DEFINE. * m4/ptrdiff.m4 (AM_TYPE_PTRDIFF_T): Use 3-argument form of AC_DEFINE. * m4/protos.m4 (AM_C_PROTOTYPES):Use 3-argument form of AC_DEFINE. * m4/obstack.m4 (AM_FUNC_OBSTACK): Use 3-argument form of AC_DEFINE. * m4/init.m4 (AM_INIT_AUTOMAKE): Use 3-argument form of AC_DEFINE. * m4/dmalloc.m4 (AM_WITH_DMALLOC): Use 3-argument form of AC_DEFINE.

m4/init.m4

# Do all the work for Automake.  This macro actually does too much --
# some checks are only needed if your package does certain things.
# But this isn't really a big deal.

# serial 1

dnl Usage:
dnl AM_INIT_AUTOMAKE(package,version, [no-define])

AC_DEFUN(AM_INIT_AUTOMAKE,
[AC_REQUIRE([AC_PROG_INSTALL])
PACKAGE=[$1]
AC_SUBST(PACKAGE)
VERSION=[$2]
AC_SUBST(VERSION)
dnl test to see if srcdir already configured
if test "`cd $srcdir && pwd`" != "`pwd`" && test -f $srcdir/config.status; then
  AC_MSG_ERROR([source directory already configured; run "make distclean" there first])
fi
ifelse([$3],,
AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version number of package]))
AC_REQUIRE([AM_SANITY_CHECK])
AC_REQUIRE([AC_ARG_PROGRAM])
dnl FIXME This is truly gross.
missing_dir=`cd $ac_aux_dir && pwd`
AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
AC_REQUIRE([AC_PROG_MAKE_SET])])

kc3-lang/automake/m4/init.m4

Commit

kc3-lang/automake /m4/init.m4