missing.m4

Branch :

Show log
Commit
Author : Alexandre Duret-Lutz
Date : 2001-08-03 08:28:21
Hash : f00ec284
Message : * m4/install-sh.m4: New file. * m4/Makefile.am (m4data_DATA): Add install-sh.m4. * m4/missing.m4 (AM_MISSING_INSTALL_SH): Move ... * m4/install-sh.m4 (AM_PROG_INSTALL_SH): ... here. Don't check for install.sh any longer, always use install-sh, don't even fall back to missing. Use $am_aux_dir, making $install_sh absolute. * m4/strip.m4 (AM_PROG_INSTALL_STRIP): Simplify, since $install_sh is absolute. * m4/init.m4: Adjust call to AM_PROG_INSTALL_SH.

m4/missing.m4

## --------------------------------------------------------- ##
## Fake the existence of programs that GNU maintainers use.  ##
## --------------------------------------------------------- ##

# serial 2

# AM_MISSING_PROG(NAME, PROGRAM)
# ------------------------------
AC_DEFUN([AM_MISSING_PROG],
[AC_REQUIRE([AM_MISSING_HAS_RUN])
$1=${$1-"${am_missing_run}$2"}
AC_SUBST($1)])


# AM_MISSING_HAS_RUN
# ------------------
# Define MISSING if not defined so far and test if it supports --run.
# If it does, set am_missing_run to use it, otherwise, to nothing.
AC_DEFUN([AM_MISSING_HAS_RUN],
[test x"${MISSING+set}" = xset ||
  MISSING="\${SHELL} `CDPATH=:; cd $ac_aux_dir && pwd`/missing"
# Use eval to expand $SHELL
if eval "$MISSING --run true"; then
  am_missing_run="$MISSING --run "
else
  am_missing_run=
  am_backtick='`'
  AC_MSG_WARN([${am_backtick}missing' script is too old or missing])
fi
])

kc3-lang/automake/m4/missing.m4

Commit

kc3-lang/automake /m4/missing.m4