kc3-lang/automake/m4/mkdirp.m4

• Show log

  Commit

• Hash : 97aaf121
  Author :
  Date : 2013-02-17T10:25:29
  

  maint: describe new versioning and branching scheme, and adjust to it
  
  See discussion about automake bug#13578 for more details and background.
  
  Basically, for the versioning scheme:
  
    - micro versions only for bug and regression fixing;
    - minor versions for new backward-compatible features, and new
      non-fatal deprecations;
    - major versions for backward-incompatibilities, complex new
      features, and major refactoring.
  
  And for the git branching scheme:
  
    + branch 'next' is for the upcoming major version;
    + branch 'master' is now for the upcoming minor version;
    + branch 'maint' is for the upcoming micro (bug-fixing) version;
    + the merging hierarchy is: 'maint' -> 'master' -> 'next'.
  
  * HACKING (Automake versioning and compatibility scheme): New.
  (Working with git): Adjust.
  * NEWS: Update and fix.
  * aclocal.in: Adjust some "FIXME" messages.
  * automake.in: Likewise.
  * m4/mkdirp.m4: Likewise.
  * t/aclocal-acdir.sh: Likewise.
  * t/aclocal-macrodir.tap: Likewise.
  * t/aclocal-macrodirs.tap: Likewise.
  * lib/Automake/Options.pm: Likewise.
  * m4/internal/ac-config-macro-dirs.m4: Likewise.
  
  Signed-off-by: Stefano Lattarini <stefano.lattarini@gmail.com>
  

Download

• m4/mkdirp.m4

• ##                                                          -*- Autoconf -*-
  # Copyright (C) 2003-2013 Free Software Foundation, Inc.
  #
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  # AM_PROG_MKDIR_P
  # ---------------
  # Check for 'mkdir -p'.
  AC_DEFUN([AM_PROG_MKDIR_P],
  [AC_PREREQ([2.60])dnl
  AC_REQUIRE([AC_PROG_MKDIR_P])dnl
  dnl FIXME we are no longer going to remove this! adjust warning
  dnl FIXME message accordingly.
  AC_DIAGNOSE([obsolete],
  [$0: this macro is deprecated, and will soon be removed.
  You should use the Autoconf-provided 'AC][_PROG_MKDIR_P' macro instead,
  and use '$(MKDIR_P)' instead of '$(mkdir_p)'in your Makefile.am files.])
  dnl Automake 1.8 to 1.9.6 used to define mkdir_p.  We now use MKDIR_P,
  dnl while keeping a definition of mkdir_p for backward compatibility.
  dnl @MKDIR_P@ is magic: AC_OUTPUT adjusts its value for each Makefile.
  dnl However we cannot define mkdir_p as $(MKDIR_P) for the sake of
  dnl Makefile.ins that do not define MKDIR_P, so we do our own
  dnl adjustment using top_builddir (which is defined more often than
  dnl MKDIR_P).
  AC_SUBST([mkdir_p], ["$MKDIR_P"])dnl
  case $mkdir_p in
    [[\\/$]]* | ?:[[\\/]]*) ;;
    */*) mkdir_p="\$(top_builddir)/$mkdir_p" ;;
  esac
  ])
  

Download