kc3-lang/automake/m4/lispdir.m4

• Show log

  Commit

• Hash : d2ca1685
  Author :
  Date : 2012-04-06T10:10:12
  

  m4: delete several obsolete macros
  
  Support for several obsolescent macros has already been deprecated,
  and their removal already announced in the documentation and in the
  NEWS file.  It's now time to finally remove them.
  
  * m4/dmalloc.m4 (fp_WITH_DMALLOC): Don't define anymore.
  * m4/maintainer.m4 (jm_MAINTAINER_MODE): Likewise.
  * m4/lispdir.m4 (ud_PATH_LISPDIR): Likewise.
  * m4/protos.m4 (fp_C_PROTOTYPES): Likewise.
  * m4/ccstdc.m4: Delete file.
  * m4/header.m4: Likewise.
  * m4/obsol-gt.m4: Likewise.
  * m4/obsol-lt.m4: Likewise.
  * m4/obsolete.m4: Likewise.
  * Makefile.am (dist_automake_ac_DATA): Don't list the deleted '.m4'
  files anymore.
  * t/confh.sh: Use 'AC_CONFIG_HEADERS' instead of the now-removed
  AM_CONFIG_HEADER.
  * t/confh.sh: Likewise.
  * t/confh4.sh: Likewise.
  * t/confh6.sh: Likewise.
  * t/confh7.sh: Likewise.
  * t/confh8.sh: Likewise.
  * t/confsub.sh: Likewise.
  * t/stamph2.sh: Likewise.
  * t/subdir6.sh: Likewise.
  * t/autohdr2.sh: Remove as obsolete.
  * t/obsolete.sh: Likewise.
  * t/list-of-tests.mk. Don't list the deleted test cases anymore.
  * NEWS: Update.
  * doc/automake.texi: Likewise.  In particular ...
  (Obsolete Macros): Remove this node altogether.
  
  Signed-off-by: Stefano Lattarini <stefano.lattarini@gmail.com>
  

Download

• m4/lispdir.m4

• ## ------------------------                                 -*- Autoconf -*-
  ## Emacs LISP file handling
  ## From Ulrich Drepper
  ## Almost entirely rewritten by Alexandre Oliva
  ## ------------------------
  # Copyright (C) 1996-2012 Free Software Foundation, Inc.
  #
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  # serial 12
  
  # AM_PATH_LISPDIR
  # ---------------
  AC_DEFUN([AM_PATH_LISPDIR],
  [AC_PREREQ([2.60])dnl
   # If set to t, that means we are running in a shell under Emacs.
   # If you have an Emacs named "t", then use the full path.
   test x"$EMACS" = xt && EMACS=
   AC_CHECK_PROGS([EMACS], [emacs xemacs], [no])
   AC_ARG_VAR([EMACS], [the Emacs editor command])
   AC_ARG_VAR([EMACSLOADPATH], [the Emacs library search path])
   AC_ARG_WITH([lispdir],
   [AS_HELP_STRING([--with-lispdir],
                   [override the default lisp directory])],
   [ lispdir="$withval"
     AC_MSG_CHECKING([where .elc files should go])
     AC_MSG_RESULT([$lispdir])],
   [
   AC_CACHE_CHECK([where .elc files should go], [am_cv_lispdir], [
     if test $EMACS != "no"; then
       if test x${lispdir+set} != xset; then
    # If $EMACS isn't GNU Emacs or XEmacs, this can blow up pretty badly
    # Some emacsen will start up in interactive mode, requiring C-x C-c to exit,
    #  which is non-obvious for non-emacs users.
    # Redirecting /dev/null should help a bit; pity we can't detect "broken"
    #  emacsen earlier and avoid running this altogether.
    AC_RUN_LOG([$EMACS -batch -q -eval '(while load-path (princ (concat (car load-path) "\n")) (setq load-path (cdr load-path)))' </dev/null >conftest.out])
  	am_cv_lispdir=`sed -n \
         -e 's,/$,,' \
         -e '/.*\/lib\/x*emacs\/site-lisp$/{s,.*/lib/\(x*emacs/site-lisp\)$,${libdir}/\1,;p;q;}' \
         -e '/.*\/share\/x*emacs\/site-lisp$/{s,.*/share/\(x*emacs/site-lisp\),${datarootdir}/\1,;p;q;}' \
         conftest.out`
         rm conftest.out
       fi
     fi
     test -z "$am_cv_lispdir" && am_cv_lispdir='${datadir}/emacs/site-lisp'
    ])
    lispdir="$am_cv_lispdir"
  ])
  AC_SUBST([lispdir])
  ])# AM_PATH_LISPDIR
  

Download