kc3-lang/automake/m4/maintainer.m4

• Show log

  Commit

• Hash : d2ca1685
  Author :
  Date : 2012-04-06T10:10:12
  

  m4: delete several obsolete macros
  
  Support for several obsolescent macros has already been deprecated,
  and their removal already announced in the documentation and in the
  NEWS file.  It's now time to finally remove them.
  
  * m4/dmalloc.m4 (fp_WITH_DMALLOC): Don't define anymore.
  * m4/maintainer.m4 (jm_MAINTAINER_MODE): Likewise.
  * m4/lispdir.m4 (ud_PATH_LISPDIR): Likewise.
  * m4/protos.m4 (fp_C_PROTOTYPES): Likewise.
  * m4/ccstdc.m4: Delete file.
  * m4/header.m4: Likewise.
  * m4/obsol-gt.m4: Likewise.
  * m4/obsol-lt.m4: Likewise.
  * m4/obsolete.m4: Likewise.
  * Makefile.am (dist_automake_ac_DATA): Don't list the deleted '.m4'
  files anymore.
  * t/confh.sh: Use 'AC_CONFIG_HEADERS' instead of the now-removed
  AM_CONFIG_HEADER.
  * t/confh.sh: Likewise.
  * t/confh4.sh: Likewise.
  * t/confh6.sh: Likewise.
  * t/confh7.sh: Likewise.
  * t/confh8.sh: Likewise.
  * t/confsub.sh: Likewise.
  * t/stamph2.sh: Likewise.
  * t/subdir6.sh: Likewise.
  * t/autohdr2.sh: Remove as obsolete.
  * t/obsolete.sh: Likewise.
  * t/list-of-tests.mk. Don't list the deleted test cases anymore.
  * NEWS: Update.
  * doc/automake.texi: Likewise.  In particular ...
  (Obsolete Macros): Remove this node altogether.
  
  Signed-off-by: Stefano Lattarini <stefano.lattarini@gmail.com>
  

Download

• m4/maintainer.m4

• # Add --enable-maintainer-mode option to configure.         -*- Autoconf -*-
  # From Jim Meyering
  
  # Copyright (C) 1996-2012 Free Software Foundation, Inc.
  #
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  # serial 8
  
  # AM_MAINTAINER_MODE([DEFAULT-MODE])
  # ----------------------------------
  # Control maintainer-specific portions of Makefiles.
  # Default is to disable them, unless 'enable' is passed literally.
  # For symmetry, 'disable' may be passed as well.  Anyway, the user
  # can override the default with the --enable/--disable switch.
  AC_DEFUN([AM_MAINTAINER_MODE],
  [m4_case(m4_default([$1], [disable]),
         [enable], [m4_define([am_maintainer_other], [disable])],
         [disable], [m4_define([am_maintainer_other], [enable])],
         [m4_define([am_maintainer_other], [enable])
          m4_warn([syntax], [unexpected argument to AM@&t@_MAINTAINER_MODE: $1])])
  AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
    dnl maintainer-mode's default is 'disable' unless 'enable' is passed
    AC_ARG_ENABLE([maintainer-mode],
      [AS_HELP_STRING([--]am_maintainer_other[-maintainer-mode],
        am_maintainer_other[ make rules and dependencies not useful
        (and sometimes confusing) to the casual installer])],
      [USE_MAINTAINER_MODE=$enableval],
      [USE_MAINTAINER_MODE=]m4_if(am_maintainer_other, [enable], [no], [yes]))
    AC_MSG_RESULT([$USE_MAINTAINER_MODE])
    AM_CONDITIONAL([MAINTAINER_MODE], [test $USE_MAINTAINER_MODE = yes])
    MAINT=$MAINTAINER_MODE_TRUE
    AC_SUBST([MAINT])dnl
  ]
  )
  

Download