configure.in

Branch :

Show log
Commit
Author : Alexandre Duret-Lutz
Date : 2003-04-24 18:48:07
Hash : ab57cf28
Message : * automake.in (scan_aclocal_m4): Do not parse ACLOCAL_AMFLAGS and glob for m4_files (We've got all local m4 files while tracing m4_include's). Diagnose ACLOCAL_M4_SOURCES as obsolete. Distribute aclocal.m4 only at the top-level. (my_glob): Remove. This fixes PR automake/11. (handle_dist): Strip leading `./' from directories. * aclocal.in (add_file): Output 'm4_include([file.m4])' instead of copying local files. (write_aclocal, parse_arguments): Bump copyright date. * configure.in: De not build m4/amversion.m4 from here ... * m4/Makefile.am ($(srcdir)/amversion.m4): ... do this here. (nodist_m4data_DATA): Use $(srcdir)/amversion.m4 instead of amversion.m4. * tests/Makefile.am (XFAIL_TESTS): Remove aclocal5.test. (TESTS): Remove aclocal2.test. Do not test aclocal.test twice. * tests/aclocal2.test: Delete (pointless). * tests/aclocal5.test: Make sure configure's dependencies are distributed. * tests/acinclude.test: Adjust to search for m4_include. * tests/dirlist.test, tests/dup3.test: Run $AUTOCONF and grep configure instead of aclocal.m4.

configure.in

# Process this file with autoconf to produce a configure script.

# Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
# Free Software Foundation, Inc.
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2, or (at your option)
# any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
# 02111-1307, USA.

AC_PREREQ(2.54)
AC_INIT([GNU Automake], [1.7a], [bug-automake@gnu.org])

AC_CONFIG_SRCDIR(automake.in)
AC_CONFIG_AUX_DIR(lib)

AC_CANONICAL_BUILD

# Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it;
# this way we can run Autoconf tests from configure without being
# bothered by `missing'.
am_AUTOCONF=${AUTOCONF-autoconf}

AM_INIT_AUTOMAKE([1.6 dist-bzip2])

# The API version is the base version.  We must guarantee
# compatibility for all releases with the same API version.
# Our current rule is that:
# * All releases, including the prereleases, in an X.Y series
#   are compatible.  So 1.5.1c is compatible with 1.5.
# * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
#   aren't the same.
APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
AC_SUBST(APIVERSION)

# A versioned directory, defined here for convenience.
pkgvdatadir="\${datadir}/automake-${APIVERSION}"
AC_SUBST(pkgvdatadir)

# $AUTOMAKE and $ACLOCAL are always run after a `cd $top_srcdir',
# hence `.' is really what we want for perllibdir and libdir.
ACLOCAL="perllibdir=./lib `pwd`/aclocal --acdir=m4 -I `pwd`/m4"
AUTOMAKE="perllibdir=./lib `pwd`/automake --libdir=lib"

AC_PATH_PROG(PERL, perl)
if test -z "$PERL"; then
   AC_MSG_ERROR([perl not found])
fi
$PERL -e 'require 5.005;' || {
   AC_MSG_ERROR([perl 5.005 or better is required])
}

# The test suite will skip some tests if tex is absent.
AC_CHECK_PROG([TEX], [tex], [tex])

# Test for Autoconf.  We run Autoconf in a subdirectory to ease
# deletion of any files created (such as those added to
# autom4te.cache).
mkdir conftest
echo 'AC''_PREREQ(2.54)' > conftest/conftest.ac
AM_RUN_LOG([cd conftest && eval $am_AUTOCONF -o /dev/null conftest.ac]) || {
   AC_MSG_ERROR([Autoconf 2.54 or better is required.
  Is it installed?  Is it in your PATH?  (try running `autoconf --version')
  Is it working?  See also config.log for error messages before this one.])
}
rm -rf conftest

# Test for ln.  We need use it to install the versioned binaries.
AC_MSG_CHECKING([whether ln works])
AC_CACHE_VAL([am_cv_prog_ln], [
rm -f conftest conftest.file
: >conftest.file
if ln conftest.file conftest 2>/dev/null; then
  am_cv_prog_ln=ln
else
  am_cv_prog_ln='cp -p'
fi
rm -f conftest conftest.file])
AC_SUBST([LN], [$am_cv_prog_ln])
result=no
test "x$am_cv_prog_ln" = xln && result=yes
AC_MSG_RESULT([$result])

# The amount we should wait after modifying files depends on the platform.
# On Windows '95, '98 and ME, files modifications have 2-seconds
# granularity and can be up to 3 seconds in the future w.r.t. the
# system clock.  When it is important to ensure one file is older
# than another we wait at least 5 seconds between creations.
case $build in
  *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
  *)               MODIFICATION_DELAY=2;;
esac
AC_SUBST([MODIFICATION_DELAY])

# Test for things needed by the test suite.
AC_PROG_EGREP
AC_PROG_FGREP

AC_CONFIG_FILES([
  Makefile
  lib/Automake/Makefile
  lib/Automake/tests/Makefile
  lib/Makefile
  lib/am/Makefile
  m4/Makefile
  tests/Makefile
  tests/defs
])

AC_OUTPUT

kc3-lang/automake/configure.in

Commit

kc3-lang/automake /configure.in