kc3-lang/automake/m4/mkdirp.m4

• Show log

  Commit

• Hash : 7a1eb9ff
  Author :
  Date : 2012-04-02T17:05:42
  

  AM_PROG_MKDIR_P: deprecate, to be removed in Automake 1.13
  
  Support for the obsolescent 'AM_PROG_MKDIR_P' macro (and its
  output variable '$(mkdir_p)') has already been deprecated in
  the documentation.  It's now time to make its use actively
  emit warnings in the 'obsolete' category as well.
  
  * automake.in (scan_autoconf_traces): Warn about 'AM_PROG_MKDIR_P'
  obsolescent if that macro is seen.
  * m4/mkdirp.m4 (AM_PROG_MKDIR_P): Warn about its own obsolescence.
  * m4/init.m4: Require 'AC_PROG_MKDIR_P', not 'AM_PROG_MKDIR_P'.
  * t/mkdirp-deprecation.sh: New test.
  * t/list-of-tests.mk: Add it.
  * syntax-check.mk (sc_mkdir_p): Delete this check as obsolete.
  (syntax_check_rules): Remove it.
  * t/gettext-macros.sh: Ensure the gettext-requiring tests will
  call aclocal and automake with the 'obsolete' warnings disabled,
  since even recent versions of gettext used the now-deprecated
  'AM_PROG_MKDIR_P' m4 macro.
  * NEWS: Update.
  
  Signed-off-by: Stefano Lattarini <stefano.lattarini@gmail.com>
  

Download

• m4/mkdirp.m4

• ##                                                          -*- Autoconf -*-
  # Copyright (C) 2003-2012 Free Software Foundation, Inc.
  #
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  # serial 3
  
  # AM_PROG_MKDIR_P
  # ---------------
  # Check for 'mkdir -p'.
  AC_DEFUN([AM_PROG_MKDIR_P],
  [AC_PREREQ([2.60])dnl
  AC_REQUIRE([AC_PROG_MKDIR_P])dnl
  dnl FIXME to be removed in Automake 1.13.
  AC_DIAGNOSE([obsolete],
  [$0: this macro is deprecated, and will soon be removed.
  You should use the Autoconf-provided 'AC][_PROG_MKDIR_P' macro instead,
  and use '$(MKDIR_P)' instead of '$(mkdir_p)'in your Makefile.am files.])
  dnl Automake 1.8 to 1.9.6 used to define mkdir_p.  We now use MKDIR_P,
  dnl while keeping a definition of mkdir_p for backward compatibility.
  dnl @MKDIR_P@ is magic: AC_OUTPUT adjusts its value for each Makefile.
  dnl However we cannot define mkdir_p as $(MKDIR_P) for the sake of
  dnl Makefile.ins that do not define MKDIR_P, so we do our own
  dnl adjustment using top_builddir (which is defined more often than
  dnl MKDIR_P).
  AC_SUBST([mkdir_p], ["$MKDIR_P"])dnl
  case $mkdir_p in
    [[\\/$]]* | ?:[[\\/]]*) ;;
    */*) mkdir_p="\$(top_builddir)/$mkdir_p" ;;
  esac
  ])
  

Download