kc3-lang/automake/m4/silent.m4

• Show log

  Commit

• Hash : f8f22fea
  Author :
  Date : 2012-02-23T19:36:20
  

  m4: do not quote `like this', as per GCS recommendation
  
  This patch converts the files comprising the automake's own build
  system to the use of new quoting format 'like this' or "like this"
  rather than `like this'.
  
  * m4/auxdir.m4, m4/ccstdc.m4, m4/depend.m4, m4/depout.m4, m4/tar.m4,
  m4/init.m4, m4/maintainer.m4, m4/make.m4, m4/missing.m4, m4/vala.m4,
  m4/mkdirp.m4, m4/sanity.m4, m4/silent.m4, m4/strip.m4: Update and
  adjust quoting format throughout, in comments and diagnostic.  Some
  minor related rewordings and reformatting since we are at it.  Bump
  serial numbers.
  

Download

• m4/silent.m4

• ##                                                          -*- Autoconf -*-
  # Copyright (C) 2009-2012 Free Software Foundation, Inc.
  #
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  # serial 3
  
  # AM_SILENT_RULES([DEFAULT])
  # --------------------------
  # Enable less verbose build rules; with the default set to DEFAULT
  # ("yes" being less verbose, "no" or empty being verbose).
  AC_DEFUN([AM_SILENT_RULES],
  [AC_ARG_ENABLE([silent-rules], [dnl
  AS_HELP_STRING(
    [--enable-silent-rules],
    [less verbose build output (undo: "make V=1")])
  AS_HELP_STRING(
    [--disable-silent-rules],
    [verbose build output (undo: "make V=0")])dnl
  ])
  case $enable_silent_rules in @%:@ (((
    yes) AM_DEFAULT_VERBOSITY=0;;
     no) AM_DEFAULT_VERBOSITY=1;;
      *) AM_DEFAULT_VERBOSITY=m4_if([$1], [yes], [0], [1]);;
  esac
  dnl
  dnl A few 'make' implementations (e.g., NonStop OS and NextStep)
  dnl do not support nested variable expansions.
  dnl See automake bug#9928 and bug#10237.
  am_make=${MAKE-make}
  AC_CACHE_CHECK([whether $am_make supports nested variables],
     [am_cv_make_support_nested_variables],
     [if AS_ECHO([['TRUE=$(BAR$(V))
  BAR0=false
  BAR1=true
  V=1
  am__doit:
  	@$(TRUE)
  .PHONY: am__doit']]) | $am_make -f - >/dev/null 2>&1; then
    am_cv_make_support_nested_variables=yes
  else
    am_cv_make_support_nested_variables=no
  fi])
  if test $am_cv_make_support_nested_variables = yes; then
    dnl Using '$V' instead of '$(V)' breaks IRIX make.
    AM_V='$(V)'
    AM_DEFAULT_V='$(AM_DEFAULT_VERBOSITY)'
  else
    AM_V=$AM_DEFAULT_VERBOSITY
    AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY
  fi
  AC_SUBST([AM_V])dnl
  AM_SUBST_NOTMAKE([AM_V])dnl
  AC_SUBST([AM_DEFAULT_V])dnl
  AM_SUBST_NOTMAKE([AM_DEFAULT_V])dnl
  AC_SUBST([AM_DEFAULT_VERBOSITY])dnl
  AM_BACKSLASH='\'
  AC_SUBST([AM_BACKSLASH])dnl
  _AM_SUBST_NOTMAKE([AM_BACKSLASH])dnl
  ])
  

Download