kc3-lang/automake/m4/lispdir.m4

• Show log

  Commit

• Hash : 09375a66
  Author :
  Date : 1999-10-03T23:43:35
  

  * m4/lispdir.m4: -batch must come before -q.
  * elisp-comp: Likewise.
  Reported by Lars Hecking <lhecking@nmrc.ucc.ie>
  * THANKS: Added Lars.
  

Download

• m4/lispdir.m4

• ## ------------------------
  ## Emacs LISP file handling
  ## From Ulrich Drepper
  ## Almost entirely rewritten by Alexandre Oliva
  ## ------------------------
  
  # serial 3
  
  AC_DEFUN(AM_PATH_LISPDIR,
   [# If set to t, that means we are running in a shell under Emacs.
    # If you have an Emacs named "t", then use the full path.
    test x"$EMACS" = xt && EMACS=
    AC_CHECK_PROGS(EMACS, emacs xemacs, no)
    if test $EMACS != "no"; then
      if test x${lispdir+set} != xset; then
        AC_CACHE_CHECK([where .elc files should go], [am_cv_lispdir], [dnl
  	am_cv_lispdir=`$EMACS -batch -q -eval '(while load-path (princ (concat (car load-path) "\n")) (setq load-path (cdr load-path)))' | sed -n -e 's,/$,,' -e '/.*\/lib\/\(x\?emacs\/site-lisp\)$/{s,,${libdir}/\1,;p;q;}' -e '/.*\/share\/\(x\?emacs\/site-lisp\)$/{s,,${datadir}/\1,;p;q;}'`
  	if test -z "$am_cv_lispdir"; then
  	  am_cv_lispdir='${datadir}/emacs/site-lisp'
  	fi
        ])
        lispdir="$am_cv_lispdir"
      fi
    fi
    AC_SUBST(lispdir)])
  

Download