kc3-lang/automake/m4/silent.m4

Branch - branch -masterv1.18- tag -v1.18.1v1.17.92v1.17.90v1.17v1.16iv1.16.92v1.16.90v1.16.5v1.16.4v1.16.3v1.16.2v1.16.1v1.16v1.15.1v1.15v1.14.1v1.14v1.13bv1.13.4v1.13.3v1.13.2bv1.13.2v1.13.1dv1.13.1bv1.13.1v1.13v1.12bv1.12.6v1.12.5v1.12.4v1.12.3v1.12.2v1.12.1v1.12.0bv1.12v1.11dv1.11bv1.11v1.10buser-dep-gen-branchpointpre-ian-conditionalspre-depend-changeng-0.5amerging-into-user-dep-genlast-merge-into-user-dep-gen-branchhandle-languagesbranchpoint-real-1-5branchpoint-1-9branchpoint-1-8branchpoint-1-7branchpoint-1-6branchpoint-1-5branchpoint-1-10Release-1-9bRelease-1-9Release-1-8dRelease-1-8bRelease-1-8Release-1-7hRelease-1-7fRelease-1-7dRelease-1-7bRelease-1-7-3bRelease-1-7-2bRelease-1-7Release-1-6fRelease-1-6dRelease-1-6bRelease-1-6-1bRelease-1-6Release-1-5dRelease-1-5bRelease-1-4jRelease-1-4hRelease-1-4fRelease-1-4dRelease-1-4bRelease-1-4Release-1-3dRelease-1-3bRelease-1-3Release-1-2hRelease-1-2gRelease-1-2eRelease-1-2dRelease-1-2cRelease-1-2bRelease-1-2Release-1-1pRelease-1-1oRelease-1-1mRelease-1-1lRelease-1-1kRelease-1-1iRelease-1-1hRelease-1-1gRelease-1-1fRelease-1-1eRelease-1-1dRelease-1-1cRelease-1-1bRelease-1-1aRelease-1-10Release-1-0Release-0-33Release-0-32Release-0-31Release-0-30Release-0-29Release-0-28Release-0-27Release-0-26Release-0-25

• Show log

  Commit

• Hash : 29d21ffc
  Author :
  Date : 2025-02-21T09:58:12
  

  m4: force newline after AM_SILENT_RULES, as before 1.17.
  
  From https://bugs.gnu.org/72267.
  
  * m4/silent.m4 (AM_SILENT_RULES): m4_newline() after the assignment.
  Report from Francis Dupont, suggestions from Francis and Nick Bowler.
  * NEWS: mention this.
  * THANKS: add Francis.
  

Download

• m4/silent.m4

• ##                                                          -*- Autoconf -*-
  # Copyright (C) 2009-2025 Free Software Foundation, Inc.
  #
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  # _AM_SILENT_RULES
  # ----------------
  # Enable less verbose build rules support.
  AC_DEFUN([_AM_SILENT_RULES],
  [AM_DEFAULT_VERBOSITY=1
  AC_ARG_ENABLE([silent-rules], [dnl
  AS_HELP_STRING(
    [--enable-silent-rules],
    [less verbose build output (undo: "make V=1")])
  AS_HELP_STRING(
    [--disable-silent-rules],
    [verbose build output (undo: "make V=0")])dnl
  ])
  dnl
  dnl A few 'make' implementations (e.g., NonStop OS and NextStep)
  dnl do not support nested variable expansions.
  dnl See automake bug#9928 and bug#10237.
  am_make=${MAKE-make}
  AC_CACHE_CHECK([whether $am_make supports nested variables],
     [am_cv_make_support_nested_variables],
     [if AS_ECHO([['TRUE=$(BAR$(V))
  BAR0=false
  BAR1=true
  V=1
  am__doit:
  	@$(TRUE)
  .PHONY: am__doit']]) | $am_make -f - >/dev/null 2>&1; then
    am_cv_make_support_nested_variables=yes
  else
    am_cv_make_support_nested_variables=no
  fi])
  AC_SUBST([AM_V])dnl
  AM_SUBST_NOTMAKE([AM_V])dnl
  AC_SUBST([AM_DEFAULT_V])dnl
  AM_SUBST_NOTMAKE([AM_DEFAULT_V])dnl
  AC_SUBST([AM_DEFAULT_VERBOSITY])dnl
  AM_BACKSLASH='\'
  AC_SUBST([AM_BACKSLASH])dnl
  _AM_SUBST_NOTMAKE([AM_BACKSLASH])dnl
  dnl Delay evaluation of AM_DEFAULT_VERBOSITY to the end to allow multiple calls
  dnl to AM_SILENT_RULES to change the default value.
  AC_CONFIG_COMMANDS_PRE([dnl
  case $enable_silent_rules in @%:@ (((
    yes) AM_DEFAULT_VERBOSITY=0;;
     no) AM_DEFAULT_VERBOSITY=1;;
  esac
  if test $am_cv_make_support_nested_variables = yes; then
    dnl Using '$V' instead of '$(V)' breaks IRIX make.
    AM_V='$(V)'
    AM_DEFAULT_V='$(AM_DEFAULT_VERBOSITY)'
  else
    AM_V=$AM_DEFAULT_VERBOSITY
    AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY
  fi
  ])dnl
  ])
  
  # AM_SILENT_RULES([DEFAULT])
  # --------------------------
  # Set the default verbosity level to DEFAULT ("yes" being less verbose, "no" or
  # empty being verbose).
  AC_DEFUN([AM_SILENT_RULES],
  [AC_REQUIRE([_AM_SILENT_RULES])
  AM_DEFAULT_VERBOSITY=m4_if([$1], [yes], [0], [1])m4_newline
  dnl We intentionally force a newline after the assignment, since a) nothing
  dnl good can come of more text following, and b) that was the behavior
  dnl before 1.17. See https://bugs.gnu.org/72267.
  ])
  

Download