kc3-lang/gnulib/m4/ld-version-script.m4

• Show log

  Commit

• Hash : f187e34f
  Author :
  Date : 2023-04-24T01:57:33
  

  Improve quoting of AS_HELP_STRING's first argument.
  
  * m4/acl.m4 (gl_FUNC_ACL_ARG): Don't underquote AS_HELP_STRING's first
  argument.
  * m4/assert.m4 (gl_ASSERT): Likewise.
  * m4/gc.m4 (gl_GC): Likewise.
  * m4/gnulib-common.m4 (gl_COMMON_BODY): Likewise.
  * m4/ld-version-script.m4 (gl_LD_VERSION_SCRIPT): Likewise.
  * m4/lib-ld.m4 (AC_LIB_PROG_LD): Likewise.
  * m4/libgmp.m4 (gl_LIBGMP): Likewise.
  * m4/regex.m4 (gl_REGEX): Likewise.
  * m4/relocatable-lib.m4 (gl_RELOCATABLE_NOP): Likewise.
  * m4/selinux-selinux-h.m4 (gl_LIBSELINUX): Likewise.
  * m4/sigsegv.m4 (gl_SIGSEGV): Likewise.
  * m4/threadlib.m4 (gl_THREADLIB_EARLY_BODY): Likewise.
  * m4/valgrind-tests.m4 (gl_VALGRIND_TESTS): Likewise.
  * m4/version-etc.m4 (gl_VERSION_ETC_FLAG): Likewise.
  * m4/xattr.m4 (gl_FUNC_XATTR): Likewise.
  * doc/manywarnings.texi (manywarnings): Likewise. This avoids the use of
  quadrigraphs.
  

Download

• m4/ld-version-script.m4

• # ld-version-script.m4 serial 6
  dnl Copyright (C) 2008-2023 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  dnl From Simon Josefsson
  
  # FIXME: The test below returns a false positive for mingw
  # cross-compiles, 'local:' statements does not reduce number of
  # exported symbols in a DLL.  Use --disable-ld-version-script to work
  # around the problem.
  
  # gl_LD_VERSION_SCRIPT
  # --------------------
  # Check if LD supports linker scripts, and define automake conditional
  # HAVE_LD_VERSION_SCRIPT if so.
  AC_DEFUN([gl_LD_VERSION_SCRIPT],
  [
    AC_ARG_ENABLE([ld-version-script],
      [AS_HELP_STRING([[--enable-ld-version-script]],
         [enable linker version script (default is enabled when possible)])],
      [have_ld_version_script=$enableval],
      [AC_CACHE_CHECK([if LD -Wl,--version-script works],
         [gl_cv_sys_ld_version_script],
         [gl_cv_sys_ld_version_script=no
          save_LDFLAGS=$LDFLAGS
          LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
          echo foo >conftest.map
          AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
            [],
            [cat > conftest.map <<EOF
  VERS_1 {
          global: sym;
  };
  
  VERS_2 {
          global: sym;
  } VERS_1;
  EOF
             AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
               [gl_cv_sys_ld_version_script=yes])])
          rm -f conftest.map
          LDFLAGS=$save_LDFLAGS])
       have_ld_version_script=$gl_cv_sys_ld_version_script])
    AM_CONDITIONAL([HAVE_LD_VERSION_SCRIPT],
      [test "$have_ld_version_script" = yes])
  ])
  

Download