kc3-lang/gnulib/m4/opendir.m4

• Show log

  Commit

• Hash : 3b1faeb2
  Author :
  Date : 2017-07-10T12:35:06
  

  Make sure $host and $host_os are defined when used.
  
  * m4/argz.m4 (gl_FUNC_ARGZ): Require AC_CANONICAL_HOST.
  * m4/closedir.m4 (gl_FUNC_CLOSEDIR): Likewise.
  * m4/csharpexec.m4 (gt_CSHARPEXEC): Likewise.
  * m4/dirfd.m4 (gl_FUNC_DIRFD): Likewise.
  * m4/expl.m4 (gl_FUNC_EXPL): Likewise.
  * m4/ls-mntd-fs.m4 (gl_LIST_MOUNTED_FILE_SYSTEMS): Likewise.
  * m4/lstat.m4 (gl_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK): Likewise.
  * m4/opendir.m4 (gl_FUNC_OPENDIR): Likewise.
  * m4/poll.m4 (gl_FUNC_POLL): Likewise.
  * m4/pselect.m4 (gl_FUNC_PSELECT): Likewise.
  * m4/ptsname.m4 (gl_FUNC_PTSNAME): Likewise.
  * m4/relocatable.m4 (gl_RELOCATABLE_BODY): Likewise.
  * m4/symlinkat.m4 (gl_FUNC_SYMLINKAT): Likewise.
  * m4/ceill.m4 (gl_FUNC_CEILL): Require AC_CANONICAL_HOST outside the
  m4_ifdef block.
  

Download

• m4/opendir.m4

• # opendir.m4 serial 5
  dnl Copyright (C) 2011-2017 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  AC_DEFUN([gl_FUNC_OPENDIR],
  [
    AC_REQUIRE([gl_DIRENT_H_DEFAULTS])
    AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  
    AC_CHECK_FUNCS([opendir])
    if test $ac_cv_func_opendir = no; then
      HAVE_OPENDIR=0
    fi
    dnl Replace opendir() for supporting the gnulib-defined fchdir() function,
    dnl to keep fchdir's bookkeeping up-to-date.
    m4_ifdef([gl_FUNC_FCHDIR], [
      gl_TEST_FCHDIR
      if test $HAVE_FCHDIR = 0; then
        if test $HAVE_OPENDIR = 1; then
          REPLACE_OPENDIR=1
        fi
      fi
    ])
    dnl Replace opendir() on OS/2 kLIBC to support dirfd() function replaced
    dnl by gnulib.
    case $host_os,$HAVE_OPENDIR in
      os2*,1)
        REPLACE_OPENDIR=1;;
    esac
  ])
  

Download