kc3-lang/gnulib/m4/calloc.m4

• Show log

  Commit

• Hash : 4fde4952
  Author :
  Date : 2006-07-05T23:35:19
  

  * lib/memcasecmp.c: Include <limits.h>.
  (memcasecmp): Don't assume UCHAR_MAX <= INT_MAX.
  * lib/strtod.c (strtod): Don't assume isspace works on negative chars.
  Don't assume isdigit succeeds only on '0' through '9'.
  
  * lib/exclude.c (IN_CTYPE_DOMAIN, is_space): Remove; no longer needed.
  All uses of is_space replaced by isspace.
  * lib/fnmatch.c (ISASCII): Remove; no longer needed.  All uses removed.
  (ISPRINT, ISDIGIT, ISALNUM, ISALPHA, ISCNTRL, ISLOWER, ISPUNCT):
  (ISSPACE, ISUPPER, ISXDIGIT): Remove; no longer needed.  All uses
  replaced by isprint etc.
  * lib/getdate.y (IN_CTYPE_DOMAIN, ISSPACE, ISALPHA, ISLOWER): Likewise.
  * lib/getusershell.c (IN_CTYPE_DOMAIN, ISSPACE): Likewise.
  * lib/memcasecmp.c (IN_CTYPE_DOMAIN, ISLOWER, TOUPPER): Likewise.
  * lib/strtod.c (IN_CTYPE_DOMAIN, ISSPACE, ISDIGIT, TOLOWER): Likewise.
  * lib/strtol.c (IN_CTYPE_DOMAIN): Likewise.
  * lib/xstrtol.c (IN_CTYPE_DOMAIN, ISSPACE): Likewise.
  
  * m4/xstrtol.m4 (gl_PREREQ_XSTRTOL): Use AC_CHECK_DECLS_ONCE
  rather than AC_CHECK_DECLS for strtoimax and strtoumax.
  * m4/getusershell.m4 (gl_PREREQ_GETUSERSHELL): Remove; no longer needed.
  All uses removed.
  * m4/strtol.m4 (gl_PREREQ_STRTOL): Likewise.
  * m4/strtoul.m4 (gl_PREREQ_STRTOUL): Likewise.
  * m4/exclude.m4 (gl_EXCLUDE): Don't check for isascii; no longer needed.
  * m4/getdate.m4 (gl_GETDATE): Likewise.
  * m4/getusershell.m4 (gl_PREREQ_GETUSERSHELL): Likewise.
  * m4/memcasecmp.m4 (gl_MEMCASECMP): Likewise.
  * m4/strtod.m4 (gl_FUNC_STRTOD): Likewise.
  * m4/strtol.m4 (gl_PREREQ_STRTOL): Likewise.
  * m4/strtoul.m4 (gl_PREREQ_STRTOUL): Likewise.
  * m4/xstrtol.m4 (gl_PREREQ_XSTRTOL): Likewise.
  * m4/exclude.m4 (gl_EXCLUDE): Don't require AC_C_INLINE; no longer
  needed.
  * m4/calloc.m4 (_AC_FUNC_CALLOC_IF): Don't require AC_HEADER_STDC;
  no longer needed.
  * m4/exclude.m4 (gl_EXCLUDE): Likewise.
  * m4/getdate.m4 (gl_GETDATE): Likewise.
  * m4/getusershell.m4 (gl_PREREQ_GETUSERSHELL): Likewise.
  * m4/memcasecmp.m4 (gl_MEMCASECMP): Likewise.
  * m4/strtod.m4 (gl_FUNC_STRTOD): Likewise.
  * m4/strtol.m4 (gl_PREREQ_STRTOL): Likewise.
  * m4/xstrtol.m4 (gl_PREREQ_XSTRTOL): Likewise.
  

Download

• m4/calloc.m4

• # calloc.m4 serial 6
  
  # Copyright (C) 2004, 2005, 2006 Free Software Foundation, Inc.
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  # Written by Jim Meyering.
  
  # Determine whether calloc (N, S) returns non-NULL when N*S is zero,
  # and returns NULL when N*S overflows.
  # If so, define HAVE_CALLOC.  Otherwise, define calloc to rpl_calloc
  # and arrange to use a calloc wrapper function that does work in that case.
  
  # _AC_FUNC_CALLOC_IF(IF-WORKS, IF-NOT)
  # -------------------------------------
  # If `calloc (0, 0)' is properly handled, run IF-WORKS, otherwise, IF-NOT.
  AC_DEFUN([_AC_FUNC_CALLOC_IF],
  [AC_REQUIRE([AC_TYPE_SIZE_T])dnl
  AC_CACHE_CHECK([for GNU libc compatible calloc], ac_cv_func_calloc_0_nonnull,
  [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
  		  [exit (!calloc (0, 0) || calloc ((size_t) -1 / 8 + 1, 8));])],
  	       [ac_cv_func_calloc_0_nonnull=yes],
  	       [ac_cv_func_calloc_0_nonnull=no],
  	       [ac_cv_func_calloc_0_nonnull=no])])
  AS_IF([test $ac_cv_func_calloc_0_nonnull = yes], [$1], [$2])
  ])# AC_FUNC_CALLOC
  
  
  # AC_FUNC_CALLOC
  # ---------------
  # Report whether `calloc (0, 0)' is properly handled, and replace calloc if
  # needed.
  AC_DEFUN([AC_FUNC_CALLOC],
  [_AC_FUNC_CALLOC_IF(
    [AC_DEFINE([HAVE_CALLOC], 1,
  	     [Define to 1 if your system has a GNU libc compatible `calloc'
  	      function, and to 0 otherwise.])],
    [AC_DEFINE([HAVE_CALLOC], 0)
     AC_LIBOBJ([calloc])
     AC_DEFINE([calloc], [rpl_calloc],
        [Define to rpl_calloc if the replacement function should be used.])])
  ])# AC_FUNC_CALLOC
  

Download