kc3-lang/gnulib/m4/sys_socket_h.m4

• Show log

  Commit

• Hash : 73f2a1c0
  Author :
  Date : 2007-06-21T17:08:44
  

  * m4/fchdir.m4 (gl_FUNC_FCHDIR): Likewise.
  * m4/iconv_h.m4 (gl_ICONV_H): Likewise.
  * m4/locale_h.m4 (gl_LOCALE_H): Likewise.
  * m4/netinet_in_h.m4 (gl_HEADER_NETINET_IN): Likewise.
  * m4/sys_select_h.m4 (gl_HEADER_SYS_SELECT): Likewise.
  * m4/sys_socket_h.m4 (gl_HEADER_SYS_SOCKET): Likewise.
  * m4/sysexits.m4 (gl_SYSEXITS): Likewise.
  SCALAR(0x828a248)
  * lib/dirent_.h: Likewise.
  * lib/iconv_.h: Likewise.
  * lib/locale_.h: Likewise.
  * lib/netinet_in_.h: Likewise.
  * lib/sys_select_.h: Likewise.
  * lib/sys_socket_.h: Likewise.
  * lib/sysexits_.h: Likewise.
  * modules/fchdir: Likewise.
  * modules/iconv_open: Likewise.
  * modules/locale: Likewise.
  * modules/netinet_in: Likewise.
  * modules/sys_select: Likewise.
  * modules/sys_socket: Likewise.
  * modules/sysexits: Likewise.
  

Download

• m4/sys_socket_h.m4

• # sys_socket_h.m4 serial 4
  dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  dnl From Simon Josefsson.
  
  AC_DEFUN([gl_HEADER_SYS_SOCKET],
  [
    AC_CACHE_CHECK([whether <sys/socket.h> is self-contained],
      [gl_cv_header_sys_socket_h_selfcontained],
      [
        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/socket.h>], [])],
          [gl_cv_header_sys_socket_h_selfcontained=yes],
          [gl_cv_header_sys_socket_h_selfcontained=no])
      ])
    if test $gl_cv_header_sys_socket_h_selfcontained = yes; then
      SYS_SOCKET_H=''
    else
      SYS_SOCKET_H='sys/socket.h'
  
      gl_CHECK_NEXT_HEADERS([sys/socket.h])
      if test $ac_cv_header_sys_socket_h = yes; then
        HAVE_SYS_SOCKET_H=1
        HAVE_WINSOCK2_H=0
        HAVE_WS2TCPIP_H=0
      else
        HAVE_SYS_SOCKET_H=0
        dnl We cannot use AC_CHECK_HEADERS_ONCE here, because that would make
        dnl the check for those headers unconditional; yet cygwin reports
        dnl that the headers are present but cannot be compiled (since on
        dnl cygwin, all socket information should come from sys/socket.h).
        AC_CHECK_HEADERS([winsock2.h ws2tcpip.h])
        if test $ac_cv_header_winsock2_h = yes; then
          HAVE_WINSOCK2_H=1
        else
          HAVE_WINSOCK2_H=0
        fi
        if test $ac_cv_header_ws2tcpip_h = yes; then
          HAVE_WS2TCPIP_H=1
        else
          HAVE_WS2TCPIP_H=0
        fi
      fi
      AC_SUBST([HAVE_SYS_SOCKET_H])
      AC_SUBST([HAVE_WINSOCK2_H])
      AC_SUBST([HAVE_WS2TCPIP_H])
    fi
    AC_SUBST([SYS_SOCKET_H])
  ])
  

Download