kc3-lang/gnulib/m4/assert_h.m4

• Show log

  Commit

• Hash : 8b401988
  Author :
  Date : 2011-05-05T22:43:18
  

  assert-h: new module, which supports C1X-style static_assert
  
  * lib/assert.in.h, m4/assert_h.m4, modules/assert-h: New files.
  * lib/verify.h: Revamp so that this can be copied into assert.h,
  while retaining the ability to use it standalone as before.
  Rename private identifiers so as not to encroach on the
  standard C namespace, since this is now used by assert.h.
  (_GL_VERIFY_TYPE): New macro, factoring out differing parts of
  the old verify_true.
  (_GL_VERIFY_TRUE): New macro, with much of the contents of
  the old verify_true.  Use _GL_VERIFY_TYPE.
  (_GL_VERIFY): New macro, with much of the contents of the old verify.
  (static_assert): New macro, if _GL_STATIC_ASSERT_H
  is defined and static_assert is not; _GL_STATIC_ASSERT_H is
  defined when this file is copied into the replacement assert.h.
  (_Static_assert): New macro, if _GL_STATIC_ASSERT_H is defined
  and _Static_assert is not built in.
  (verify_true, verify): Define only if _GL_STATIC_ASSERT_H is not
  defined, and use the new macros mentioned above.
  * doc/posix-headers/assert.texi: Document this.
  

Download

• m4/assert_h.m4

• # assert-h.m4
  dnl Copyright (C) 2011 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  dnl From Paul Eggert.
  
  AC_DEFUN([gl_ASSERT_H],
  [
    ASSERT_H=
    AC_CACHE_CHECK([for static_assert], [gl_cv_static_assert],
      [AC_COMPILE_IFELSE(
         [AC_LANG_PROGRAM(
            [[#include <assert.h>
              static_assert (2 + 2 == 4, "arithmetic doesn't work");
            ]],
            [[
              static_assert (sizeof (char) == 1, "sizeof doesn't work");
            ]])],
         [gl_cv_static_assert=yes],
         [gl_cv_static_assert=no])])
    if test $gl_cv_static_assert = no; then
      ASSERT_H=assert.h
      gl_NEXT_HEADERS([assert.h])
    fi
    AC_SUBST([ASSERT_H])
    AM_CONDITIONAL([GL_GENERATE_ASSERT_H], [test -n "$ASSERT_H"])
  ])
  

Download