kc3-lang/gnulib/m4/sys_ioctl_h.m4

• Show log

  Commit

• Hash : e5c4538a
  Author :
  Date : 2011-05-04T14:26:56
  

  maint: remove useless REPLACE_*_H macros
  
  There are still a few modules, like iconv_h.m4, that still
  use older paradigms where GNULIB_POSIXCHECK is unsupported
  and where gl_REPLACE_<HEADER>_H is still essential.  But since
  we are moving away from that style, I see no reason to keep
  the idiom for the modules that don't need it.
  
  * m4/arpa_inet_h.m4 (gl_REPLACE_ARPA_INET_H): Delete.
  * m4/dirent_h.m4 (gl_REPLACE_DIRENT_H): Likewise.
  * m4/locale_h.m4 (gl_REPLACE_LOCALE_H): Likewise.
  * m4/poll_h.m4 (gl_REPLACE_POLL_H): Likewise.
  * m4/spawn_h.m4 (gl_REPLACE_SPAWN_H): Likewise.
  * m4/sys_ioctl_h.m4 (gl_REPLACE_SYS_IOCTL_H): Likewise.
  * m4/wchar_h.m4 (gl_REPLACE_WCHAR_H): Likewise.
  * m4/btowc.m4: Update callers.
  * m4/dirfd.m4: Likewise.
  * m4/duplocale.m4: Likewise.
  * m4/fchdir.m4: Likewise.
  * m4/fdopendir.m4: Likewise.
  * m4/inet_ntop.m4: Likewise.
  * m4/inet_pton.m4: Likewise.
  * m4/ioctl.m4: Likewise.
  * m4/mbrlen.m4: Likewise.
  * m4/mbrtowc.m4: Likewise.
  * m4/mbsinit.m4: Likewise.
  * m4/mbsnrtowcs.m4: Likewise.
  * m4/mbsrtowcs.m4: Likewise.
  * m4/poll.m4: Likewise.
  * m4/setlocale.m4: Likewise.
  * m4/wcrtomb.m4: Likewise.
  * m4/wcsnrtombs.m4: Likewise.
  * m4/wcsrtombs.m4: Likewise.
  * m4/wctob.m4: Likewise.
  * m4/wcwidth.m4: Likewise.
  * modules/posix_spawn: Likewise.
  * modules/posix_spawn_file_actions_addclose: Likewise.
  * modules/posix_spawn_file_actions_adddup2: Likewise.
  * modules/posix_spawn_file_actions_addopen: Likewise.
  * modules/posix_spawn_file_actions_destroy: Likewise.
  * modules/posix_spawn_file_actions_init: Likewise.
  * modules/posix_spawnattr_destroy: Likewise.
  * modules/posix_spawnattr_getflags: Likewise.
  * modules/posix_spawnattr_getpgroup: Likewise.
  * modules/posix_spawnattr_getschedparam: Likewise.
  * modules/posix_spawnattr_getschedpolicy: Likewise.
  * modules/posix_spawnattr_getsigdefault: Likewise.
  * modules/posix_spawnattr_getsigmask: Likewise.
  * modules/posix_spawnattr_init: Likewise.
  * modules/posix_spawnattr_setflags: Likewise.
  * modules/posix_spawnattr_setpgroup: Likewise.
  * modules/posix_spawnattr_setschedparam: Likewise.
  * modules/posix_spawnattr_setschedpolicy: Likewise.
  * modules/posix_spawnattr_setsigdefault: Likewise.
  * modules/posix_spawnattr_setsigmask: Likewise.
  * modules/posix_spawnp: Likewise.
  
  Signed-off-by: Eric Blake <eblake@redhat.com>
  

Download

• m4/sys_ioctl_h.m4

• # sys_ioctl_h.m4 serial 10
  dnl Copyright (C) 2008-2011 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  dnl Written by Bruno Haible.
  
  AC_DEFUN([gl_SYS_IOCTL_H],
  [
    dnl Use AC_REQUIRE here, so that the default behavior below is expanded
    dnl once only, before all statements that occur in other macros.
    AC_REQUIRE([gl_SYS_IOCTL_H_DEFAULTS])
  
    AC_CHECK_HEADERS_ONCE([sys/ioctl.h])
    if test $ac_cv_header_sys_ioctl_h = yes; then
      HAVE_SYS_IOCTL_H=1
      dnl Test whether <sys/ioctl.h> declares ioctl(), or whether some other
      dnl header file, such as <unistd.h> or <stropts.h>, is needed for that.
      AC_CACHE_CHECK([whether <sys/ioctl.h> declares ioctl],
        [gl_cv_decl_ioctl_in_sys_ioctl_h],
        [dnl We cannot use AC_CHECK_DECL because it produces its own messages.
         AC_COMPILE_IFELSE(
           [AC_LANG_PROGRAM(
              [AC_INCLUDES_DEFAULT([#include <sys/ioctl.h>])],
              [(void) ioctl;])],
           [gl_cv_decl_ioctl_in_sys_ioctl_h=yes],
           [gl_cv_decl_ioctl_in_sys_ioctl_h=no])
        ])
    else
      HAVE_SYS_IOCTL_H=0
    fi
    AC_SUBST([HAVE_SYS_IOCTL_H])
    dnl <sys/ioctl.h> is always overridden, because of GNULIB_POSIXCHECK.
    gl_CHECK_NEXT_HEADERS([sys/ioctl.h])
  
    dnl Check for declarations of anything we want to poison if the
    dnl corresponding gnulib module is not in use.
    gl_WARN_ON_USE_PREPARE([[#include <sys/ioctl.h>
  /* Some platforms declare ioctl in the wrong header.  */
  #if !(defined __GLIBC__ && !defined __UCLIBC__)
  # include <unistd.h>
  #endif
      ]], [ioctl])
  ])
  
  AC_DEFUN([gl_SYS_IOCTL_MODULE_INDICATOR],
  [
    dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
    AC_REQUIRE([gl_SYS_IOCTL_H_DEFAULTS])
    gl_MODULE_INDICATOR_SET_VARIABLE([$1])
    dnl Define it also as a C macro, for the benefit of the unit tests.
    gl_MODULE_INDICATOR_FOR_TESTS([$1])
  ])
  
  AC_DEFUN([gl_SYS_IOCTL_H_DEFAULTS],
  [
    GNULIB_IOCTL=0;         AC_SUBST([GNULIB_IOCTL])
    dnl Assume proper GNU behavior unless another module says otherwise.
    SYS_IOCTL_H_HAVE_WINSOCK2_H=0; AC_SUBST([SYS_IOCTL_H_HAVE_WINSOCK2_H])
    SYS_IOCTL_H_HAVE_WINSOCK2_H_AND_USE_SOCKETS=0;
                          AC_SUBST([SYS_IOCTL_H_HAVE_WINSOCK2_H_AND_USE_SOCKETS])
    REPLACE_IOCTL=0;      AC_SUBST([REPLACE_IOCTL])
  ])
  

Download