kc3-lang/gnulib/m4/valgrind-helper.m4

• Show log

  Commit

• Hash : b744688d
  Author :
  Date : 2024-04-04T11:16:15
  

  Make the serial numbers in *.m4 files effective.
  
  Reported by Sam James in
  <https://lists.gnu.org/archive/html/bug-gnulib/2024-04/msg00051.html>.
  
  * m4/*.m4: Apply sed -e '1s|^# \(.*[.]m4\) serial |# \1\n# serial |'.
  

Download

• m4/valgrind-helper.m4

• # valgrind-helper.m4
  # serial 3
  dnl Copyright (C) 2023-2024 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  # Enables support for running the generated binaries under valgrind if
  # - the valgrind header files are installed, and
  # - the user desires so.
  AC_DEFUN_ONCE([gl_VALGRIND_HELPER],
  [
    AC_ARG_WITH([valgrind],
      [AS_HELP_STRING([[--with-valgrind]],
         [enable support for running the binaries under valgrind])],
      [if test "$withval" != no; then
         support_valgrind=1
       else
         support_valgrind=0
       fi
      ],
      [support_valgrind=0])
    if test $support_valgrind = 1; then
      AC_CHECK_HEADERS([valgrind/valgrind.h])
      if test $ac_cv_header_valgrind_valgrind_h != yes; then
        AC_MSG_ERROR([cannot enable valgrind support: <valgrind/valgrind.h> not found])
      fi
    fi
    AC_DEFINE_UNQUOTED([ENABLE_VALGRIND_SUPPORT], [$support_valgrind],
      [Define to 1 to include support for running the binaries under valgrind,
       or to 0 otherwise.])
  ])
  

Download