kc3-lang/gnulib/m4/execvpe.m4

• Show log

  Commit

• Hash : 959415ca
  Author :
  Date : 2023-01-22T12:34:17
  

  Resolve conflicts for functions introduced in Android API level 21.
  
  * m4/execvpe.m4 (gl_FUNC_EXECVPE): Conditionally set REPLACE_EXECVPE.
  * m4/linkat.m4 (gl_FUNC_LINKAT): Conditionally set REPLACE_LINKAT.
  * m4/readlinkat.m4 (gl_FUNC_READLINKAT): Conditionally set
  REPLACE_READLINKAT.
  * m4/symlinkat.m4 (gl_FUNC_SYMLINKAT): Conditionally set
  REPLACE_SYMLINKAT.
  * m4/truncate.m4 (gl_FUNC_TRUNCATE): Conditionally set REPLACE_TRUNCATE.
  * lib/unistd.in.h (execvpe, linkat, readlinkat, symlinkat, truncate):
  Disable _GL_CXXALIASWARN invocation on non-glibc systems.
  

Download

• m4/execvpe.m4

• # execvpe.m4 serial 3
  dnl Copyright (C) 2020-2023 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  AC_DEFUN([gl_FUNC_EXECVPE],
  [
    AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
    AC_REQUIRE([AC_CANONICAL_HOST])
  
    dnl Persuade glibc <unistd.h> to declare execvpe().
    AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  
    case "$host_os" in
      mingw*) REPLACE_EXECVPE=1 ;;
      *)
        gl_CHECK_FUNCS_ANDROID([execvpe], [[#include <unistd.h>]])
        if test $ac_cv_func_execvpe != yes; then
          HAVE_EXECVPE=0
          case "$gl_cv_onwards_func_execvpe" in
            future*) REPLACE_EXECVPE=1 ;;
          esac
        fi
        ;;
    esac
  ])
  

Download