kc3-lang/gnulib/m4/gc.m4

• Show log

  Commit

• Hash : f187e34f
  Author :
  Date : 2023-04-24T01:57:33
  

  Improve quoting of AS_HELP_STRING's first argument.
  
  * m4/acl.m4 (gl_FUNC_ACL_ARG): Don't underquote AS_HELP_STRING's first
  argument.
  * m4/assert.m4 (gl_ASSERT): Likewise.
  * m4/gc.m4 (gl_GC): Likewise.
  * m4/gnulib-common.m4 (gl_COMMON_BODY): Likewise.
  * m4/ld-version-script.m4 (gl_LD_VERSION_SCRIPT): Likewise.
  * m4/lib-ld.m4 (AC_LIB_PROG_LD): Likewise.
  * m4/libgmp.m4 (gl_LIBGMP): Likewise.
  * m4/regex.m4 (gl_REGEX): Likewise.
  * m4/relocatable-lib.m4 (gl_RELOCATABLE_NOP): Likewise.
  * m4/selinux-selinux-h.m4 (gl_LIBSELINUX): Likewise.
  * m4/sigsegv.m4 (gl_SIGSEGV): Likewise.
  * m4/threadlib.m4 (gl_THREADLIB_EARLY_BODY): Likewise.
  * m4/valgrind-tests.m4 (gl_VALGRIND_TESTS): Likewise.
  * m4/version-etc.m4 (gl_VERSION_ETC_FLAG): Likewise.
  * m4/xattr.m4 (gl_FUNC_XATTR): Likewise.
  * doc/manywarnings.texi (manywarnings): Likewise. This avoids the use of
  quadrigraphs.
  

Download

• m4/gc.m4

• # gc.m4 serial 14
  dnl Copyright (C) 2005-2023 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  AC_DEFUN([gl_GC],
  [
    AC_ARG_WITH([libgcrypt],
      AS_HELP_STRING([[--with-libgcrypt]], [use libgcrypt for low-level crypto]),
      libgcrypt=$withval, libgcrypt=no)
    if test "$libgcrypt" != no; then
      # gc-libgcrypt.c will fail on startup if we don't have
      # version 1.4.4 or later, so test for it early. */
      gl_good_gcrypt=no
      AM_PATH_LIBGCRYPT([1.4.4], [gl_good_gcrypt=yes],
        [AC_MSG_ERROR([libgcrypt is too old])])
      if test "x$gl_good_gcrypt" != xno; then
        dnl Ignore the value of LIBGCRYPT_LIBS, because it does not include
        dnl '-lgpg-error'.
        AC_LIB_HAVE_LINKFLAGS([gcrypt], [gpg-error], [#include <gcrypt.h>])
        LIB_CRYPTO="$LIBGCRYPT"
      else
        AC_MSG_ERROR([libgcrypt not found])
      fi
    fi
    AC_SUBST([LIB_CRYPTO])
  
    AC_REQUIRE([AC_C_RESTRICT])
  ])
  

Download