Hash :
bf3b90e8
Author :
Date :
2023-01-19T21:55:29
Fix warnings for functions introduced in Android API level 23. * m4/fbufmode.m4 (gl_FUNC_FBUFMODE): Test for __flbf, __fbufsize using gl_CHECK_FUNCS_ANDROID instead of AC_CHECK_FUNCS_ONCE. * m4/filenamecat.m4 (gl_FILE_NAME_CONCAT_LGPL): Test for mempcpy using gl_CHECK_FUNCS_ANDROID instead of AC_CHECK_FUNCS_ONCE. * m4/fpurge.m4 (gl_FUNC_FPURGE): Test for __fpurge using gl_CHECK_FUNCS_ANDROID instead of AC_CHECK_FUNCS_ONCE. * m4/freadable.m4 (gl_FUNC_FREADABLE): Test for __freadable using gl_CHECK_FUNCS_ANDROID instead of AC_CHECK_FUNCS_ONCE. * m4/fwritable.m4 (gl_FUNC_FWRITABLE): Test for __fwritable using gl_CHECK_FUNCS_ANDROID instead of AC_CHECK_FUNCS_ONCE. * m4/getpass.m4 (gl_FUNC_GETPASS_GNU): Test for __fsetlocking using gl_CHECK_FUNCS_ANDROID instead of AC_CHECK_FUNCS_ONCE. * m4/mempcpy.m4 (gl_FUNC_MEMPCPY): Test for mempcpy using gl_CHECK_FUNCS_ANDROID instead of AC_CHECK_FUNCS. * m4/mkfifoat.m4 (gl_FUNC_MKFIFOAT): Test for mkfifoat using gl_CHECK_FUNCS_ANDROID instead of AC_CHECK_FUNCS_ONCE. * m4/mkostemp.m4 (gl_FUNC_MKOSTEMP): Test for mkostemp using gl_CHECK_FUNCS_ANDROID instead of AC_CHECK_FUNCS_ONCE. * m4/mkostemps.m4 (gl_FUNC_MKOSTEMPS): Test for mkostemps using gl_CHECK_FUNCS_ANDROID instead of AC_CHECK_FUNCS_ONCE. * m4/pty.m4 (gl_FUNC_LOGIN_TTY): Test for login_tty using gl_CHECK_FUNCS_ANDROID instead of AC_CHECK_FUNCS. * m4/sethostname.m4 (gl_FUNC_SETHOSTNAME): Test for sethostname using gl_CHECK_FUNCS_ANDROID instead of AC_CHECK_FUNCS. * m4/strerror_r.m4 (gl_FUNC_STRERROR_R_WORKS): Test for strerror_r using gl_CHECK_FUNCS_ANDROID instead of AC_CHECK_FUNCS_ONCE. * m4/wmempcpy.m4 (gl_FUNC_WMEMPCPY): Test for wmempcpy using gl_CHECK_FUNCS_ANDROID instead of AC_CHECK_FUNCS_ONCE.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89
# getpass.m4 serial 20
dnl Copyright (C) 2002-2003, 2005-2006, 2009-2023 Free Software Foundation,
dnl Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.
# Provide a getpass() function if the system doesn't have it.
AC_DEFUN_ONCE([gl_FUNC_GETPASS],
[
AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
dnl Persuade Solaris <unistd.h> and <stdlib.h> to declare getpass().
AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
dnl Persuade Android <unistd.h> to not define getpass() as an inline function.
AC_DEFINE([NO_INLINE_GETPASS], [1], [Define to 1 on Android.])
AC_CHECK_FUNCS_ONCE([getpass])
if test $ac_cv_func_getpass = no; then
HAVE_GETPASS=0
fi
])
# Provide the GNU getpass() implementation. It supports passwords of
# arbitrary length (not just 8 bytes as on HP-UX).
AC_DEFUN([gl_FUNC_GETPASS_GNU],
[
AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
AC_REQUIRE([gl_FUNC_GETPASS])
if test $ac_cv_func_getpass = yes; then
AC_CACHE_CHECK([for getpass without length limitations],
[gl_cv_func_getpass_good],
[AC_EGREP_CPP([Lucky GNU user],
[
#include <features.h>
#ifdef __GNU_LIBRARY__
#if (__GLIBC__ >= 2) && !defined __UCLIBC__
Lucky GNU user
#endif
#endif
],
[gl_cv_func_getpass_good=yes],
[gl_cv_func_getpass_good=no])
])
if test $gl_cv_func_getpass_good != yes; then
REPLACE_GETPASS_FOR_GETPASS_GNU=1
fi
fi
])
# Prerequisites of lib/getpass.c.
AC_DEFUN([gl_PREREQ_GETPASS], [
AC_CHECK_HEADERS_ONCE([stdio_ext.h termios.h])
gl_CHECK_FUNCS_ANDROID([__fsetlocking], [[#include <stdio_ext.h>]])
AC_CHECK_DECLS([__fsetlocking],,,
[[#include <stdio.h>
#if HAVE_STDIO_EXT_H
#include <stdio_ext.h>
#endif]])
AC_CHECK_DECLS_ONCE([fflush_unlocked])
AC_CHECK_DECLS_ONCE([flockfile])
AC_CHECK_DECLS_ONCE([fputs_unlocked])
AC_CHECK_DECLS_ONCE([funlockfile])
AC_CHECK_DECLS_ONCE([putc_unlocked])
gl_HAVE_TCGETATTR
dnl We can't use AC_CHECK_FUNC here, because tcsetattr() is defined as a
dnl static inline function when compiling for Android 4.4 or older.
AC_CACHE_CHECK([for tcsetattr], [gl_cv_func_tcsetattr],
[AC_LINK_IFELSE(
[AC_LANG_PROGRAM(
[[#include <termios.h>
struct termios x;
]],
[[return tcsetattr(0,0,&x);]])
],
[gl_cv_func_tcsetattr=yes],
[gl_cv_func_tcsetattr=no])
])
if test $gl_cv_func_tcsetattr = yes; then
HAVE_TCSETATTR=1
else
HAVE_TCSETATTR=0
fi
AC_DEFINE_UNQUOTED([HAVE_TCSETATTR], [$HAVE_TCSETATTR],
[Define to 1 if the system has the 'tcsetattr' function.])
])