kc3-lang/gnulib/m4/iswblank.m4

• Show log

  Commit

• Hash : facb752a
  Author :
  Date : 2023-01-22T12:41:14
  

  Resolve conflicts for functions introduced in Android API level 21.
  
  * m4/fts.m4 (gl_FUNC_FTS_CORE): Use rpl_* symbols also when the system
  will have fts_open in a future version.
  * m4/iswblank.m4 (gl_FUNC_ISWBLANK): Conditionally set REPLACE_ISWBLANK.
  * m4/mbtowc.m4 (gl_FUNC_MBTOWC): Conditionally set REPLACE_MBTOWC.
  * m4/vdprintf.m4 (gl_REPLACE_VDPRINTF): Conditionally set
  REPLACE_VDPRINTF.
  * m4/wcsnrtombs.m4 (gl_FUNC_WCSNRTOMBS): Conditionally set
  REPLACE_WCSNRTOMBS.
  

Download

• m4/iswblank.m4

• # iswblank.m4 serial 7
  dnl Copyright (C) 2011-2023 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  AC_DEFUN([gl_FUNC_ISWBLANK],
  [
    AC_REQUIRE([gl_WCTYPE_H_DEFAULTS])
    AC_REQUIRE([gl_WCTYPE_H])
    dnl Persuade glibc <wctype.h> to declare iswblank().
    AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
    gl_CHECK_FUNCS_ANDROID([iswblank], [[#include <wctype.h>]])
    AC_CHECK_DECLS([iswblank], , , [[
      #include <wchar.h>
      #include <wctype.h>
    ]])
    if test $ac_cv_func_iswblank = no; then
      HAVE_ISWBLANK=0
      if test $ac_cv_have_decl_iswblank = yes \
         || case "$gl_cv_onwards_func_iswblank" in \
              future*) true ;; \
              *) false ;; \
            esac; then
        REPLACE_ISWBLANK=1
      fi
    fi
    if test $HAVE_ISWCNTRL = 0 || test $REPLACE_ISWCNTRL = 1; then
      dnl Redefine all of iswcntrl, ..., towupper in <wctype.h>.
      :
    else
      if test $HAVE_ISWBLANK = 0 || test $REPLACE_ISWBLANK = 1; then
        dnl Redefine only iswblank.
        :
      fi
    fi
  
  ])
  

Download