kc3-lang/gnulib/m4/link.m4

• Show log

  Commit

• Hash : 73839625
  Author :
  Date : 2023-02-17T22:58:36
  

  Improve cross-compilation for midipix.
  
  Reported by Ørjan Malde <red@foxi.me> at
  <https://lists.gnu.org/archive/html/bug-gnulib/2023-02/msg00131.html>.
  
  This patch handles the cases where midipix acts like Linux.
  
  * m4/chmod.m4 (gl_FUNC_CHMOD): Treat midipix like Linux with glibc or
  musl libc.
  * m4/d-ino.m4 (gl_CHECK_TYPE_STRUCT_DIRENT_D_INO): Likewise.
  * m4/fchdir.m4 (gl_FUNC_FCHDIR): Likewise.
  * m4/getcwd.m4 (gl_FUNC_GETCWD_NULL): Likewise.
  * m4/link.m4 (gl_FUNC_LINK): Likewise.
  * m4/linkat.m4 (gl_FUNC_LINKAT): Likewise.
  * m4/lstat.m4 (gl_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK): Likewise.
  * m4/mkdir.m4 (gl_FUNC_MKDIR): Likewise.
  * m4/pselect.m4 (gl_FUNC_PSELECT): Likewise.
  * m4/ptsname.m4 (gl_FUNC_PTSNAME): Likewise.
  * m4/readlink.m4 (gl_FUNC_READLINK): Likewise.
  * m4/rename.m4 (gl_FUNC_RENAME): Likewise.
  * m4/rmdir.m4 (gl_FUNC_RMDIR): Likewise.
  * m4/select.m4 (gl_FUNC_SELECT): Likewise.
  * m4/sleep.m4 (gl_FUNC_SLEEP): Likewise.
  * m4/stat.m4 (gl_FUNC_STAT): Likewise.
  * m4/symlink.m4 (gl_FUNC_SYMLINK): Likewise.
  * m4/symlinkat.m4 (gl_FUNC_SYMLINKAT): Likewise.
  * m4/unlink.m4 (gl_FUNC_UNLINK): Likewise.
  * m4/usleep.m4 (gl_FUNC_USLEEP): Likewise.
  

Download

• m4/link.m4

• # link.m4 serial 12
  dnl Copyright (C) 2009-2023 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  AC_DEFUN([gl_FUNC_LINK],
  [
    AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
    AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
    AC_CHECK_FUNCS_ONCE([link])
    if test $ac_cv_func_link = no; then
      HAVE_LINK=0
    else
      AC_CACHE_CHECK([whether link obeys POSIX],
        [gl_cv_func_link_works],
        [touch conftest.a
         # Assume that if we have lstat, we can also check symlinks.
         if test $ac_cv_func_lstat = yes; then
           ln -s conftest.a conftest.lnk
         fi
         AC_RUN_IFELSE(
           [AC_LANG_PROGRAM(
             [[#include <unistd.h>
               #include <stdio.h>
             ]],
             [[int result = 0;
               if (!link ("conftest.a", "conftest.b/"))
                 result |= 1;
  #if HAVE_LSTAT
               if (!link ("conftest.lnk/", "conftest.b"))
                 result |= 2;
               if (rename ("conftest.a", "conftest.b"))
                 result |= 4;
               if (!link ("conftest.b", "conftest.lnk"))
                 result |= 8;
  #endif
               return result;
             ]])],
           [gl_cv_func_link_works=yes], [gl_cv_func_link_works=no],
           [case "$host_os" in
                               # Guess yes on Linux systems.
              linux-* | linux) gl_cv_func_link_works="guessing yes" ;;
                               # Guess yes on systems that emulate the Linux system calls.
              midipix*)        gl_cv_func_link_works="guessing yes" ;;
                               # Guess yes on glibc systems.
              *-gnu* | gnu*)   gl_cv_func_link_works="guessing yes" ;;
                               # If we don't know, obey --enable-cross-guesses.
              *)               gl_cv_func_link_works="$gl_cross_guess_normal" ;;
            esac
           ])
         rm -f conftest.a conftest.b conftest.lnk])
      case "$gl_cv_func_link_works" in
        *yes) ;;
        *)
          REPLACE_LINK=1
          ;;
      esac
    fi
  ])
  

Download