kc3-lang/gnulib/m4/readlinkat.m4

• Show log

  Commit

• Hash : 959415ca
  Author :
  Date : 2023-01-22T12:34:17
  

  Resolve conflicts for functions introduced in Android API level 21.
  
  * m4/execvpe.m4 (gl_FUNC_EXECVPE): Conditionally set REPLACE_EXECVPE.
  * m4/linkat.m4 (gl_FUNC_LINKAT): Conditionally set REPLACE_LINKAT.
  * m4/readlinkat.m4 (gl_FUNC_READLINKAT): Conditionally set
  REPLACE_READLINKAT.
  * m4/symlinkat.m4 (gl_FUNC_SYMLINKAT): Conditionally set
  REPLACE_SYMLINKAT.
  * m4/truncate.m4 (gl_FUNC_TRUNCATE): Conditionally set REPLACE_TRUNCATE.
  * lib/unistd.in.h (execvpe, linkat, readlinkat, symlinkat, truncate):
  Disable _GL_CXXALIASWARN invocation on non-glibc systems.
  

Download

• m4/readlinkat.m4

• # serial 8
  # See if we need to provide readlinkat replacement.
  
  dnl Copyright (C) 2009-2023 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  # Written by Eric Blake.
  
  AC_DEFUN([gl_FUNC_READLINKAT],
  [
    AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
    AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
    gl_CHECK_FUNCS_ANDROID([readlinkat], [[#include <unistd.h>]])
    AC_REQUIRE([gl_FUNC_READLINK])
    if test $ac_cv_func_readlinkat = no; then
      HAVE_READLINKAT=0
      case "$gl_cv_onwards_func_readlinkat" in
        future*) REPLACE_READLINKAT=1 ;;
      esac
    else
      AC_CACHE_CHECK([whether readlinkat signature is correct],
        [gl_cv_decl_readlinkat_works],
        [AC_COMPILE_IFELSE(
           [AC_LANG_PROGRAM(
             [[#include <unistd.h>
               /* Check whether original declaration has correct type.  */
               ssize_t readlinkat (int, char const *, char *, size_t);]])],
           [gl_cv_decl_readlinkat_works=yes],
           [gl_cv_decl_readlinkat_works=no])])
      # Assume readlinkat has the same bugs as readlink,
      # as is the case on OS X 10.10 with trailing slashes.
      case $gl_cv_decl_readlinkat_works,$gl_cv_func_readlink_trailing_slash,$gl_cv_func_readlink_truncate in
        *yes,*yes,*yes)
          ;;
        *)
          REPLACE_READLINKAT=1
          ;;
      esac
    fi
  ])
  

Download