kc3-lang/gnulib/m4/strtoll.m4

• Show log

  Commit

• Hash : 4e38f4a0
  Author :
  Date : 2023-03-16T16:02:02
  

  strtol, strtoll, strtoul, strtoull: Make ISO C 23 compliant.
  
  * lib/strtol.c (INTERNAL (strtol)): Treat 'b' and base 2 like 'x' and
  base 16. Based on glibc commit 64924422a99690d147a166b4de3103f3bf3eaf6c
  by Joseph Myers.
  * m4/strtol.m4 (gl_FUNC_STRTOL): Test also whether parsing binary
  integers works. Update cross-compilation guesses.
  * m4/strtoll.m4 (gl_FUNC_STRTOLL): Likewise.
  * m4/strtoul.m4 (gl_FUNC_STRTOUL): Likewise.
  * m4/strtoull.m4 (gl_FUNC_STRTOULL): Likewise.
  * tests/test-strtol.c (main): Add tests of parsing binary integers.
  * tests/test-strtoll.c (main): Likewise.
  * tests/test-strtoul.c (main): Likewise.
  * tests/test-strtoull.c (main): Likewise.
  * doc/posix-functions/strtol.texi: Mention the problem with parsing
  binary integers.
  * doc/posix-functions/strtoll.texi: Likewise.
  * doc/posix-functions/strtoul.texi: Likewise.
  * doc/posix-functions/strtoull.texi: Likewise.
  

Download

• m4/strtoll.m4

• # strtoll.m4 serial 10
  dnl Copyright (C) 2002, 2004, 2006, 2008-2023 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  AC_DEFUN([gl_FUNC_STRTOLL],
  [
    AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
    AC_REQUIRE([AC_CANONICAL_HOST])
    AC_CHECK_FUNCS([strtoll])
    if test $ac_cv_func_strtoll = yes; then
      AC_CACHE_CHECK([whether strtoll works],
        [gl_cv_func_strtoll_works],
        [AC_RUN_IFELSE(
           [AC_LANG_PROGRAM(
              [[#include <stdlib.h>]],
              [[int result = 0;
                char *term;
                /* This test fails on Minix and native Windows.  */
                {
                  const char input[] = "0x";
                  (void) strtoll (input, &term, 16);
                  if (term != input + 1)
                    result |= 1;
                }
                /* This test fails on pre-C23 platforms.  */
                {
                  const char input[] = "0b1";
                  (void) strtoll (input, &term, 2);
                  if (term != input + 3)
                    result |= 2;
                }
                return result;
              ]])
           ],
           [gl_cv_func_strtoll_works=yes],
           [gl_cv_func_strtoll_works=no],
           [case "$host_os" in
                                  # Guess no on native Windows.
              mingw*)             gl_cv_func_strtoll_works="guessing no" ;;
                                  # Guess no on glibc systems.
              *-gnu* | gnu*)      gl_cv_func_strtoll_works="guessing no" ;;
                                  # Guess no on musl systems.
              *-musl* | midipix*) gl_cv_func_strtoll_works="guessing no" ;;
              *)                  gl_cv_func_strtoll_works="$gl_cross_guess_normal" ;;
            esac
           ])
      ])
      case "$gl_cv_func_strtoll_works" in
        *yes) ;;
        *)    REPLACE_STRTOLL=1 ;;
      esac
    else
      HAVE_STRTOLL=0
    fi
  ])
  
  # Prerequisites of lib/strtoll.c.
  AC_DEFUN([gl_PREREQ_STRTOLL], [
    :
  ])
  

Download