kc3-lang/gnulib/m4/check-math-lib.m4

• Show log

  Commit

• Hash : cb1827fb
  Author :
  Date : 2024-04-05T16:04:59
  

  roundl: Fix a link error on Linux/powerpc64le.
  
  * m4/check-math-lib.m4 (gl_CHECK_MATH_LIB): Accept an additional TYPE
  argument.
  * m4/isfinite.m4 (gl_ISFINITE): Use the type 'double'.
  * m4/isinf.m4 (gl_ISINF): Likewise.
  * m4/round.m4 (gl_FUNC_ROUND): Likewise.
  * m4/roundf.m4 (gl_FUNC_ROUNDF): Use the type 'float'.
  * m4/roundl.m4 (gl_FUNC_ROUNDL): Use the type 'long double'.
  

Download

• m4/check-math-lib.m4

• # check-math-lib.m4
  # serial 6
  dnl Copyright (C) 2007, 2009-2024 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  dnl
  dnl gl_CHECK_MATH_LIB (VARIABLE, TYPE, EXPRESSION [, EXTRA-CODE])
  dnl
  dnl Sets the shell VARIABLE according to the libraries needed by EXPRESSION
  dnl (that operates on a variable x of type TYPE) to compile and link: to the
  dnl empty string if no extra libraries are needed, to "-lm" if -lm is needed,
  dnl or to "missing" if it does not compile and link either way.
  dnl
  dnl Example: gl_CHECK_MATH_LIB([ROUNDF_LIBM], [float], [x = roundf (x);])
  AC_DEFUN([gl_CHECK_MATH_LIB], [
    saved_LIBS="$LIBS"
    $1=missing
    for libm in "" "-lm"; do
      LIBS="$saved_LIBS $libm"
      AC_LINK_IFELSE([AC_LANG_PROGRAM([[
           #ifndef __NO_MATH_INLINES
           # define __NO_MATH_INLINES 1 /* for glibc */
           #endif
           #include <math.h>
           $4
           $2 x;]],
        [$3])],
        [$1=$libm
  break])
    done
    LIBS="$saved_LIBS"
  ])
  

Download