kc3-lang/gnulib/m4/wctrans.m4

• Show log

  Commit

• Hash : 9ef347ea
  Author :
  Date : 2024-04-05T12:04:59
  

  Update for NetBSD 9.3 and 10.0.
  
  * doc/*/*.texi: Update for NetBSD 9.3 and 10.0.
  * m4/expm1l.m4 (gl_FUNC_EXPM1L): Update comments and cross-compilation
  guess.
  * m4/log1pl.m4 (gl_FUNC_LOG1PL_WORKS): Likewise.
  * m4/log2l.m4 (gl_FUNC_LOG2L_WORKS): Likewise.
  * m4/printf.m4 (gl_SWPRINTF_DIRECTIVE_LA): Likewise.
  * m4/remainderl.m4 (gl_FUNC_REMAINDERL_WORKS): Likewise.
  * m4/fcntl.m4: Update comments.
  * m4/fenv-environment.m4: Likewise.
  * m4/fenv-exceptions-trapping.m4: Likewise.
  * m4/fnmatch.m4: Likewise.
  * m4/getcwd-abort-bug.m4: Likewise.
  * m4/iswdigit.m4: Likewise.
  * m4/iswxdigit.m4: Likewise.
  * m4/modfl.m4: Likewise.
  * m4/wcscmp.m4: Likewise.
  * m4/wcsncmp.m4: Likewise.
  * m4/wctrans.m4: Likewise.
  * m4/wcwidth.m4: Likewise.
  

Download

• m4/wctrans.m4

• # wctrans.m4
  # serial 4
  dnl Copyright (C) 2011-2024 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  AC_DEFUN_ONCE([gl_FUNC_WCTRANS],
  [
    AC_REQUIRE([gl_WCTYPE_H_DEFAULTS])
    AC_REQUIRE([gl_WCTYPE_H])
    AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
    HAVE_WCTRANS=$HAVE_WCTRANS_T
    if test $HAVE_WCTRANS = 1; then
      AC_CACHE_CHECK([whether wctrans works],
        [gl_cv_func_wctrans_works],
        [AC_RUN_IFELSE(
           [AC_LANG_SOURCE([[
              #include <wchar.h>
              #include <wctype.h>
              int main ()
              {
                /* This test fails on NetBSD 10.0.  */
                return (wctrans ("tolower") == (wctrans_t)0);
              }
           ]])],
           [gl_cv_func_wctrans_works=yes], [gl_cv_func_wctrans_works=no],
           [case "$host_os" in
                       # Guess no on NetBSD.
              netbsd*) gl_cv_func_wctrans_works="guessing no" ;;
                       # Guess yes otherwise.
              *)       gl_cv_func_wctrans_works="guessing yes" ;;
            esac
           ])
        ])
      case "$gl_cv_func_wctrans_works" in
        *yes) ;;
        *) REPLACE_WCTRANS=1 ;;
      esac
    fi
  ])
  

Download