kc3-lang/gnulib/m4/link-follow.m4

• Show log

  Commit

• Hash : a933e8ee
  Author :
  Date : 2009-06-14T17:58:39
  

  link-follow: fix the "checking..." message to not mention trailing slash
  
  * m4/link-follow.m4 (gl_AC_FUNC_LINK_FOLLOWS_SYMLINK): This test has
  never considered trailing slashes.
  

Download

• m4/link-follow.m4

• # serial 11
  dnl Run a program to determine whether link(2) follows symlinks.
  dnl Set LINK_FOLLOWS_SYMLINKS accordingly.
  
  # Copyright (C) 1999-2001, 2004-2006, 2009 Free Software Foundation, Inc.
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  AC_DEFUN([gl_AC_FUNC_LINK_FOLLOWS_SYMLINK],
  [dnl
    AC_CACHE_CHECK([whether link(2) dereferences a symlink],
  		 gl_ac_cv_func_link_follows_symlink,
    [
      # Create a regular file.
      echo > conftest.file
      AC_TRY_RUN(
        [
  #       include <sys/types.h>
  #       include <sys/stat.h>
  #       include <unistd.h>
  #       include <stdlib.h>
  
  #       define SAME_INODE(Stat_buf_1, Stat_buf_2) \
  	  ((Stat_buf_1).st_ino == (Stat_buf_2).st_ino \
  	   && (Stat_buf_1).st_dev == (Stat_buf_2).st_dev)
  
  	int
  	main ()
  	{
  	  const char *file = "conftest.file";
  	  const char *sym = "conftest.sym";
  	  const char *hard = "conftest.hard";
  	  struct stat sb_file, sb_hard;
  
  	  /* Create a symlink to the regular file. */
  	  if (symlink (file, sym))
  	    abort ();
  
  	  /* Create a hard link to that symlink.  */
  	  if (link (sym, hard))
  	    abort ();
  
  	  if (lstat (hard, &sb_hard))
  	    abort ();
  	  if (lstat (file, &sb_file))
  	    abort ();
  
  	  /* If the dev/inode of hard and file are the same, then
  	     the link call followed the symlink.  */
  	  return SAME_INODE (sb_hard, sb_file) ? 0 : 1;
  	}
        ],
        gl_ac_cv_func_link_follows_symlink=yes,
        gl_ac_cv_func_link_follows_symlink=no,
        gl_ac_cv_func_link_follows_symlink=yes dnl We're cross compiling.
      )
    ])
    if test $gl_ac_cv_func_link_follows_symlink = yes; then
      AC_DEFINE([LINK_FOLLOWS_SYMLINKS], [1],
        [Define if `link(2)' dereferences symbolic links.])
    fi
  ])
  

Download