kc3-lang/gnulib/m4/fdopen.m4

• Show log

  Commit

• Hash : 09001dfb
  Author :
  Date : 2011-09-24T18:08:50
  

  fdopen: Support for MSVC 9.
  
  * m4/fdopen.m4 (gl_FUNC_FDOPEN): Set REPLACE_FDOPEN also if
  HAVE_MSVC_INVALID_PARAMETER_HANDLER is 1.
  * lib/fdopen.c: Include msvc-inval.h.
  (fdopen_nothrow): New function.
  (rpl_fdopen): Use it.
  * modules/fdopen (Depends-on): Add msvc-inval.
  * modules/fclose-tests (Depends-on): Add fdopen.
  * modules/fflush-tests (Depends-on): Likewise.
  * modules/fgetc-tests (Depends-on): Likewise.
  * modules/fputc-tests (Depends-on): Likewise.
  * modules/fread-tests (Depends-on): Likewise.
  * modules/freopen-tests (Depends-on): Likewise.
  * modules/fseeko-tests (Depends-on): Likewise.
  * modules/ftello-tests (Depends-on): Likewise.
  * modules/fwrite-tests  (Depends-on): Likewise.
  * doc/posix-functions/fdopen.texi: Mention the problem on MSVC.
  

Download

• m4/fdopen.m4

• # fdopen.m4 serial 2
  dnl Copyright (C) 2011 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  AC_DEFUN([gl_FUNC_FDOPEN],
  [
    AC_REQUIRE([gl_STDIO_H_DEFAULTS])
    AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
    AC_REQUIRE([gl_MSVC_INVAL])
    if test $HAVE_MSVC_INVALID_PARAMETER_HANDLER = 1; then
      REPLACE_FDOPEN=1
    else
      dnl Test whether fdopen() sets errno when it fails due to a bad fd argument.
      AC_CACHE_CHECK([whether fdopen sets errno], [gl_cv_func_fdopen_works],
        [
          AC_RUN_IFELSE(
            [AC_LANG_SOURCE([[
  #include <stdio.h>
  #include <errno.h>
  int
  main (void)
  {
    FILE *fp;
    errno = 0;
    fp = fdopen (-1, "r");
    if (fp != NULL)
      return 1;
    if (errno == 0)
      return 2;
    return 0;
  }]])],
            [gl_cv_func_fdopen_works=yes],
            [gl_cv_func_fdopen_works=no],
            [case "$host_os" in
               mingw*) gl_cv_func_fdopen_works="guessing no" ;;
               *)      gl_cv_func_fdopen_works="guessing yes" ;;
             esac
            ])
        ])
      case "$gl_cv_func_fdopen_works" in
        *no) REPLACE_FDOPEN=1 ;;
      esac
    fi
  ])
  
  dnl Prerequisites of lib/fdopen.c.
  AC_DEFUN([gl_PREREQ_FDOPEN], [])
  

Download