kc3-lang/gnulib/m4/time_r.m4

• Show log

  Commit

• Hash : c7857d58
  Author :
  Date : 2007-03-01T21:24:55
  

  Followup to the 2007-02-12 patch, using suggestions from Bruno Haible in
  <http://lists.gnu.org/archive/html/bug-gnulib/2007-02/msg00136.html>.
  * doc/gnulib-tool.texi (Initial import): Mention _FILE_OFFSET_BITS
  as another example.
  * lib/time_.h: Fix misspelling.
  * m4/nanosleep.m4 (gl_FUNC_NANOSLEEP):
  Require gl_HEADER_TIME_H_DEFAULTS.
  * m4/strptime.m4 (gl_FUNC_STRPTIME): Likewise.
  * m4/time_r.m4 (gl_TIME_R): Likewise.
  * m4/timegm.m4 (gl_FUNC_TIMEGM): Likewise.
  

Download

• m4/time_r.m4

• dnl Reentrant time functions like localtime_r.
  
  dnl Copyright (C) 2003, 2006, 2007 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  dnl Written by Paul Eggert.
  
  AC_DEFUN([gl_TIME_R],
  [
   dnl Persuade glibc and Solaris <time.h> to declare localtime_r.
    AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  
    AC_REQUIRE([gl_HEADER_TIME_H_DEFAULTS])
    AC_REQUIRE([AC_C_RESTRICT])
  
    AC_CACHE_CHECK([whether localtime_r is compatible with its POSIX signature],
      [gl_cv_time_r_posix],
      [AC_TRY_COMPILE(
         [#include <time.h>],
         [/* We don't need to append 'restrict's to the argument types,
  	   even though the POSIX signature has the 'restrict's,
  	   since C99 says they can't affect type compatibility.  */
  	struct tm * (*ptr) (time_t const *, struct tm *) = localtime_r;
          if (ptr) return 0;],
         [gl_cv_time_r_posix=yes],
         [gl_cv_time_r_posix=no])])
    if test $gl_cv_time_r_posix = yes; then
      REPLACE_LOCALTIME_R=0
    else
      REPLACE_LOCALTIME_R=1
      AC_LIBOBJ([time_r])
      gl_PREREQ_TIME_R
    fi
  ])
  
  # Prerequisites of lib/time_r.c.
  AC_DEFUN([gl_PREREQ_TIME_R], [
    :
  ])
  

Download