kc3-lang/gnulib/m4/timespec.m4

• Show log

  Commit

• Hash : 0fecb046
  Author :
  Date : 2005-09-16T06:52:14
  

  * MODULES.html.sh (File system functions): Add stat-time.
  * lib/stat-time.h: New file.
  * lib/timespec.h (ST_TIME_CMP_NS, ST_TIME_CMP, ATIME_CMP, CTIME_CMP):
  (MTIME_CMP, TIMESPEC_NS): Remove.  Now done by stat-time.h,
  in a different way.
  (timespec_cmp): New function.
  * m4/st_mtim.m4: Remove.  Superseded by...
  * m4/stat-time.m4: New file.
  * m4/timespec.m4 (gl_TIMESPEC): Require AC_C_INLINE.
  Do not invoke AC_STRUCT_ST_MTIM_NSEC; no longer needed.
  * modules/stat-time: New file.
  * modules/timespec (Files): Remove m4/st_mtim.m4; this
  is now done in a different way, by the stat-time module.
  

Download

• m4/timespec.m4

• #serial 11
  
  # Copyright (C) 2000, 2001, 2003, 2004, 2005 Free Software Foundation, Inc.
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  dnl From Jim Meyering
  
  AC_DEFUN([gl_TIMESPEC],
  [
    AC_LIBSOURCES([timespec.h])
  
    dnl Prerequisites of lib/timespec.h.
    AC_REQUIRE([AC_C_INLINE])
    AC_REQUIRE([AC_HEADER_TIME])
    AC_CHECK_HEADERS_ONCE(sys/time.h)
    gl_CHECK_TYPE_STRUCT_TIMESPEC
  
    dnl Persuade glibc <time.h> to declare nanosleep().
    AC_REQUIRE([AC_GNU_SOURCE])
  
    AC_CHECK_DECLS(nanosleep, , , [#include <time.h>])
  ])
  
  dnl Define HAVE_STRUCT_TIMESPEC if `struct timespec' is declared
  dnl in time.h or sys/time.h.
  
  AC_DEFUN([gl_CHECK_TYPE_STRUCT_TIMESPEC],
  [
    dnl Persuade pedantic Solaris to declare struct timespec.
    AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  
    AC_REQUIRE([AC_HEADER_TIME])
    AC_CHECK_HEADERS_ONCE(sys/time.h)
    AC_CACHE_CHECK([for struct timespec], fu_cv_sys_struct_timespec,
      [AC_TRY_COMPILE(
        [
  #      if TIME_WITH_SYS_TIME
  #       include <sys/time.h>
  #       include <time.h>
  #      else
  #       if HAVE_SYS_TIME_H
  #        include <sys/time.h>
  #       else
  #        include <time.h>
  #       endif
  #      endif
        ],
        [static struct timespec x; x.tv_sec = x.tv_nsec;],
        fu_cv_sys_struct_timespec=yes,
        fu_cv_sys_struct_timespec=no)
      ])
  
    if test $fu_cv_sys_struct_timespec = yes; then
      AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
  	      [Define if struct timespec is declared in <time.h>. ])
    fi
  ])
  

Download