kc3-lang/gnulib/m4/ld-output-def.m4

• Show log

  Commit

• Hash : 85d1d48f
  Author :
  Date : 2020-08-16T12:28:42
  

  Fix quoting of AC_LANG_PROGRAM arguments.
  
  * m4/fdopendir.m4 (gl_FUNC_FDOPENDIR): Quote the AC_LANG_PROGRAM
  arguments through [[...]].
  * m4/fpending.m4 (gl_FUNC_FPENDING): Likewise.
  * m4/fpurge.m4 (gl_FUNC_FPURGE): Likewise.
  * m4/fseeko.m4 (gl_FUNC_FSEEKO): Likewise.
  * m4/ld-output-def.m4 (gl_LD_OUTPUT_DEF): Likewise.
  * m4/ld-version-script.m4 (gl_LD_VERSION_SCRIPT): Likewise.
  * m4/linkat.m4 (gl_FUNC_LINKAT): Likewise.
  * m4/mountlist.m4 (gl_MOUNTLIST): Likewise.
  * m4/sys_ioctl_h.m4 (gl_SYS_IOCTL_H): Likewise.
  * m4/ungetc.m4 (gl_FUNC_UNGETC_WORKS): Likewise.
  * m4/warn-on-use.m4 (gl_WARN_ON_USE_PREPARE): Likewise.
  * m4/warnings.m4 (gl_COMPILER_OPTION_IF): Likewise.
  * m4/wcstok.m4 (gl_FUNC_WCSTOK): Likewise.
  * m4/wctype_h.m4 (gl_WCTYPE_H): Likewise.
  

Download

• m4/ld-output-def.m4

• # ld-output-def.m4 serial 3
  dnl Copyright (C) 2008-2020 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  dnl From Simon Josefsson
  
  # gl_LD_OUTPUT_DEF()
  # -------------
  # Check if linker supports -Wl,--output-def and define automake
  # conditional HAVE_LD_OUTPUT_DEF if it is.
  AC_DEFUN([gl_LD_OUTPUT_DEF],
  [
    AC_CACHE_CHECK([if gcc/ld supports -Wl,--output-def],
      [gl_cv_ld_output_def],
      [if test "$enable_shared" = no; then
         gl_cv_ld_output_def="not needed, shared libraries are disabled"
       else
         gl_ldflags_save=$LDFLAGS
         LDFLAGS="-Wl,--output-def,conftest.def"
         AC_LINK_IFELSE([AC_LANG_PROGRAM([[]])],
                     [gl_cv_ld_output_def=yes],
                     [gl_cv_ld_output_def=no])
         rm -f conftest.def
         LDFLAGS="$gl_ldflags_save"
       fi])
    AM_CONDITIONAL([HAVE_LD_OUTPUT_DEF], test "x$gl_cv_ld_output_def" = "xyes")
  ])
  

Download