kc3-lang/gnulib/m4/wcsdup.m4

• Show log

  Commit

• Hash : b1f65faa
  Author :
  Date : 2024-10-17T21:52:41
  

  Use a warranty disclaimer in all-permissive license notices.
  
  * etc/license-notices/unlimited: Add a short warranty disclaimer
  sentence.
  * m4/*.m4: Update.
  * build-aux/prefix-gnulib-mk: Likewise.
  * HACKING: Likewise.
  

Download

• m4/wcsdup.m4

• # wcsdup.m4
  # serial 4
  dnl Copyright (C) 2011-2024 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  dnl This file is offered as-is, without any warranty.
  
  AC_DEFUN([gl_FUNC_WCSDUP],
  [
    AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
    AC_CACHE_CHECK([for wcsdup],
      [gl_cv_func_wcsdup],
      [AC_LINK_IFELSE(
         [AC_LANG_PROGRAM(
            [[#include <wchar.h>
            ]GL_MDA_DEFINES],
            [[return wcsdup (L"hello") != NULL;]])
         ],
         [gl_cv_func_wcsdup=yes],
         [gl_cv_func_wcsdup=no])
      ])
    if test $gl_cv_func_wcsdup = no; then
      HAVE_WCSDUP=0
    fi
  ])
  

Download