kc3-lang/gnulib/m4/exp2f.m4

• Show log

  Commit

• Hash : bff4a106
  Author :
  Date : 2012-03-08T20:24:53
  

  New module 'exp2f'.
  
  * lib/math.in.h (exp2f): New declaration.
  * lib/exp2f.c: New file.
  * m4/exp2f.m4: New file.
  * m4/math_h.m4 (gl_MATH_H): Test whether exp2f is declared.
  (gl_MATH_H_DEFAULTS): Initialize GNULIB_EXP2F, HAVE_DECL_EXP2F.
  * modules/math (Makefile.am): Substitute GNULIB_EXP2F, HAVE_DECL_EXP2F.
  * modules/exp2f: New file.
  * tests/test-math-c++.cc: Check the declaration of exp2f.
  * doc/posix-functions/exp2f.texi: Mention the new module and the
  IRIX problem.
  

Download

• m4/exp2f.m4

• # exp2f.m4 serial 1
  dnl Copyright (C) 2011-2012 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  AC_DEFUN([gl_FUNC_EXP2F],
  [
    AC_REQUIRE([gl_MATH_H_DEFAULTS])
    AC_REQUIRE([gl_FUNC_EXP2])
  
    dnl Persuade glibc <math.h> to declare exp2f().
    AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  
    dnl Test whether exp2f() exists. Assume that exp2f(), if it exists, is
    dnl defined in the same library as exp2().
    save_LIBS="$LIBS"
    LIBS="$LIBS $EXP2_LIBM"
    AC_CHECK_FUNCS([exp2f])
    LIBS="$save_LIBS"
    if test $ac_cv_func_exp2f = yes; then
      HAVE_EXP2F=1
      EXP2F_LIBM="$EXP2_LIBM"
      dnl Also check whether it's declared.
      dnl IRIX 6.5 has exp2f() in libm but doesn't declare it in <math.h>.
      AC_CHECK_DECL([exp2f], , [HAVE_DECL_EXP2F=0], [[#include <math.h>]])
    else
      HAVE_EXP2F=0
      HAVE_DECL_EXP2F=0
      dnl Find libraries needed to link lib/exp2f.c.
      EXP2F_LIBM="$EXP2_LIBM"
    fi
    AC_SUBST([EXP2F_LIBM])
  ])
  

Download