kc3-lang/gnulib/m4/gc-random.m4

• Show log

  Commit

• Hash : 04c1ac69
  Author :
  Date : 2012-01-05T23:44:15
  

  Use ', not `, for quoting output.
  
  * build-aux/announce-gen (usage, sizes, print_news_deltas)
  (print_changelog_deltas, get_tool_versions, main program):
  * build-aux/git-version-gen:
  * build-aux/gitlog-to-changelog (usage, parse_amend_file):
  * build-aux/move-if-change (help):
  * build-aux/useless-if-before-free (usage, main program):
  * check-module (parse_module_file, usage)
  (find_included_lib_files, check_module):
  * lib/argmatch.c (main) [TEST]:
  * lib/argp-help.c (_help):
  * lib/getopt1.c (main) [TEST]:
  * lib/git-merge-changelog.c (usage):
  * lib/xstrtol-error.c (xstrtol_error):
  * m4/alloca.m4 (_AC_LIBOBJ_ALLOCA):
  * m4/argz.m4 (gl_FUNC_ARGZ):
  * m4/bison.m4 (gl_BISON):
  * m4/calloc.m4 (gl_FUNC_CALLOC_GNU):
  * m4/extensions.m4 (AC_USE_SYSTEM_EXTENSIONS):
  * m4/flexmember.m4 (AC_C_FLEXIBLE_ARRAY_MEMBER):
  * m4/fpending.m4 (gl_PREREQ_FPENDING):
  * m4/gc-random.m4 (gl_GC_RANDOM):
  * m4/intl.m4 (gt_CHECK_DECL):
  * m4/link-follow.m4 (gl_FUNC_LINK_FOLLOWS_SYMLINK):
  * m4/longlong.m4 (AC_TYPE_LONG_LONG_INT)
  (AC_TYPE_UNSIGNED_LONG_LONG_INT):
  * m4/ls-mntd-fs.m4 (gl_LIST_MOUNTED_FILE_SYSTEMS):
  * m4/lstat.m4 (gl_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK):
  * m4/onceonly.m4 (AC_CHECK_FUNCS_ONCE):
  * m4/posixver.m4 (gl_DEFAULT_POSIX2_VERSION):
  * tests/test-dirname.c (main):
  * tests/test-getpass.c (main):
  * tests/test-iconvme.c (main):
  * tests/test-parse-datetime.c (LOG):
  * tests/test-xstrtoimax.sh:
  * tests/test-xstrtol.sh:
  * tests/test-xstrtoll.sh:
  * tests/test-xstrtoumax.sh:
  * tests/unigbrk/test-uc-is-grapheme-break.c (main):
  * top/GNUmakefile (abort-due-to-no-makefile):
  Quote 'like this', not `like this', as per the recent change to
  the GNU coding standards.
  

Download

• m4/gc-random.m4

• # gc-random.m4 serial 6
  dnl Copyright (C) 2005-2012 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  AC_DEFUN([gl_GC_RANDOM],
  [
    # Devices with randomness.
    # FIXME: Are these the best defaults?
  
    AC_REQUIRE([AC_CANONICAL_HOST])dnl
  
    case "$host_os" in
      *openbsd* | *mirbsd*)
        NAME_OF_RANDOM_DEVICE="/dev/srandom"
        NAME_OF_PSEUDO_RANDOM_DEVICE="/dev/prandom"
        NAME_OF_NONCE_DEVICE="/dev/urandom"
        ;;
  
      *netbsd*)
        NAME_OF_RANDOM_DEVICE="/dev/srandom"
        NAME_OF_PSEUDO_RANDOM_DEVICE="/dev/urandom"
        NAME_OF_NONCE_DEVICE="/dev/urandom"
        ;;
  
      *solaris* | *irix* | *dec-osf* )
        NAME_OF_RANDOM_DEVICE="/dev/random"
        NAME_OF_PSEUDO_RANDOM_DEVICE="/dev/random"
        NAME_OF_NONCE_DEVICE="/dev/random"
        ;;
  
      *)
        NAME_OF_RANDOM_DEVICE="/dev/random"
        NAME_OF_PSEUDO_RANDOM_DEVICE="/dev/urandom"
        NAME_OF_NONCE_DEVICE="/dev/urandom"
        ;;
    esac
  
    AC_MSG_CHECKING([device with (strong) random data...])
    AC_ARG_ENABLE([random-device],
          AS_HELP_STRING([--enable-random-device],
                  [device with (strong) randomness (for Nettle)]),
          NAME_OF_RANDOM_DEVICE=$enableval)
    AC_MSG_RESULT([$NAME_OF_RANDOM_DEVICE])
  
    AC_MSG_CHECKING([device with pseudo random data...])
    AC_ARG_ENABLE([pseudo-random-device],
          AS_HELP_STRING([--enable-pseudo-random-device],
                  [device with pseudo randomness (for Nettle)]),
          NAME_OF_PSEUDO_RANDOM_DEVICE=$enableval)
    AC_MSG_RESULT([$NAME_OF_PSEUDO_RANDOM_DEVICE])
  
    AC_MSG_CHECKING([device with unpredictable data for nonces...])
    AC_ARG_ENABLE([nonce-device],
          AS_HELP_STRING([--enable-nonce-device],
                  [device with unpredictable nonces (for Nettle)]),
          NAME_OF_NONCE_DEVICE=$enableval)
    AC_MSG_RESULT([$NAME_OF_NONCE_DEVICE])
  
    if test "$cross_compiling" != yes; then
      if test "$NAME_OF_RANDOM_DEVICE" != "no"; then
        AC_CHECK_FILE([$NAME_OF_RANDOM_DEVICE],,
          AC_MSG_WARN([[Device '$NAME_OF_RANDOM_DEVICE' does not exist, consider to use --enable-random-device]]))
      fi
      if test "$NAME_OF_PSEUDO_RANDOM_DEVICE" != "no"; then
        AC_CHECK_FILE([$NAME_OF_PSEUDO_RANDOM_DEVICE],,
          AC_MSG_WARN([[Device '$NAME_OF_PSEUDO_RANDOM_DEVICE' does not exist, consider to use --enable-pseudo-random-device]]))
      fi
      if test "$NAME_OF_NONCE_DEVICE" != "no"; then
        AC_CHECK_FILE([$NAME_OF_NONCE_DEVICE],,
          AC_MSG_WARN([[Device '$NAME_OF_NONCE_DEVICE' does not exist, consider to use --enable-nonce-device]]))
      fi
    else
      AC_MSG_NOTICE([[Cross compiling, assuming random devices exists on the target host...]])
    fi
  
    # FIXME?: Open+read 42 bytes+close twice and compare data.  Should differ.
  
    AC_DEFINE_UNQUOTED([NAME_OF_RANDOM_DEVICE], ["$NAME_OF_RANDOM_DEVICE"],
                     [defined to the name of the (strong) random device])
    AC_DEFINE_UNQUOTED([NAME_OF_PSEUDO_RANDOM_DEVICE],
                           "$NAME_OF_PSEUDO_RANDOM_DEVICE",
                     [defined to the name of the pseudo random device])
    AC_DEFINE_UNQUOTED([NAME_OF_NONCE_DEVICE], ["$NAME_OF_NONCE_DEVICE"],
                     [defined to the name of the unpredictable nonce device])
  ])
  

Download