kc3-lang/gnulib/m4/sys_resource_h.m4

• Show log

  Commit

• Hash : 189ef2bc
  Author :
  Date : 2012-04-13T00:48:57
  

  New module 'getrusage'.
  
  * lib/sys_resource.in.h: Include arg-nonnull.h, c++defs.h,
  warn-on-use.h.
  (getrusage): New declaration.
  * lib/getrusage.c: New file.
  * m4/getrusage.m4: New file.
  * m4/sys_resource_h.m4 (gl_HEADER_SYS_RESOURCE): Test whether getrusage
  is declared.
  (gl_SYS_RESOURCE_H_DEFAULTS): Initialize GNULIB_GETRUSAGE,
  HAVE_GETRUSAGE.
  * modules/sys_resource (Depends-on): Add snippet/arg-nonnull,
  snippet/c++defs, snippet/warn-on-use.
  (Makefile.am): Update generation of sys/resource.h. Substitute
  GNULIB_GETRUSAGE, HAVE_GETRUSAGE.
  * modules/getrusage: New file.
  * doc/posix-functions/getrusage.texi: Mention the new module.
  

Download

• m4/sys_resource_h.m4

• # sys_resource_h.m4 serial 2
  dnl Copyright (C) 2012 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  AC_DEFUN([gl_HEADER_SYS_RESOURCE],
  [
    AC_REQUIRE([gl_SYS_RESOURCE_H_DEFAULTS])
    dnl <sys/resource.h> is always overridden, because of GNULIB_POSIXCHECK.
    gl_CHECK_NEXT_HEADERS([sys/resource.h])
    if test $ac_cv_header_sys_resource_h = yes; then
      HAVE_SYS_RESOURCE_H=1
    else
      HAVE_SYS_RESOURCE_H=0
    fi
    AC_SUBST([HAVE_SYS_RESOURCE_H])
  
    dnl Check for declarations of anything we want to poison if the
    dnl corresponding gnulib module is not in use.
    gl_WARN_ON_USE_PREPARE([[
  #if HAVE_SYS_RESOURCE_H
  /* At least FreeBSD 5.0 needs extra headers before <sys/resource.h>
     will compile.  */
  # include <sys/types.h>
  # include <sys/time.h>
  # include <sys/resource.h>
  #endif
      ]],
      [getrusage])
  ])
  
  AC_DEFUN([gl_SYS_RESOURCE_MODULE_INDICATOR],
  [
    dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
    AC_REQUIRE([gl_SYS_RESOURCE_H_DEFAULTS])
    gl_MODULE_INDICATOR_SET_VARIABLE([$1])
    dnl Define it also as a C macro, for the benefit of the unit tests.
    gl_MODULE_INDICATOR_FOR_TESTS([$1])
  ])
  
  AC_DEFUN([gl_SYS_RESOURCE_H_DEFAULTS],
  [
    GNULIB_GETRUSAGE=0;     AC_SUBST([GNULIB_GETRUSAGE])
    dnl Assume proper GNU behavior unless another module says otherwise.
    HAVE_GETRUSAGE=1;       AC_SUBST([HAVE_GETRUSAGE])
  ])
  

Download