kc3-lang/gnulib/m4/timer_time.m4

• Show log

  Commit

• Hash : d0738c76
  Author :
  Date : 2012-03-06T15:02:40
  

  timer-time: link explicitly with pthreads on glibc
  
  To support static linking we need to explicitly
  specify the pthreads library which is referenced
  (but not used on modern Linux kernels at least).
  
  * m4/timer_time.m4 (LIB_TIMER_TIME): Add -lpthread
  when newer GLIBC is detected as that contains
  the pthread emulation.
  * modules/timer-time: Depend on threadlib to
  pull in the appropriate library to link
  

Download

• m4/timer_time.m4

• # timer_time.m4 serial 1
  dnl Copyright (C) 2011-2012 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  # Check for timer_settime, and set LIB_TIMER_TIME.
  
  AC_DEFUN([gl_TIMER_TIME],
  [
    dnl Based on clock_time.m4. See details there.
  
    AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
    AC_REQUIRE([gl_THREADLIB])
  
    LIB_TIMER_TIME=
    AC_SUBST([LIB_TIMER_TIME])
    gl_saved_libs=$LIBS
      AC_SEARCH_LIBS([timer_settime], [rt posix4],
                     [test "$ac_cv_search_timer_settime" = "none required" ||
                      LIB_TIMER_TIME=$ac_cv_search_timer_settime])
      dnl GLIBC uses threads to emulate posix timers when kernel support
      dnl is not available (like Linux < 2.6 or when used with kFreeBSD)
      dnl Now the pthread lib is linked automatically in the normal case,
      dnl but when linking statically, it needs to be explicitly specified.
      AC_EGREP_CPP([Thread],
        [
  #include <features.h>
  #ifdef __GNU_LIBRARY__
   #if ((__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2) || (__GLIBC__ > 2)) \
       && !defined __UCLIBC__
    Thread emulation available
   #endif
  #endif
        ],
        [LIB_TIMER_TIME="$LIBMULTITHREAD $LIB_TIMER_TIME"])
      AC_CHECK_FUNCS([timer_settime])
    LIBS=$gl_saved_libs
  ])
  

Download