kc3-lang/gnulib/m4/gc-random.m4

• Show log

  Commit

• Hash : b5895556
  Author :
  Date : 2008-04-09T08:24:35
  

  Avoid some more autoconf warnings.
  
  * m4/acl.m4 (gl_FUNC_ACL): s/AC_HELP_STRING/AS_HELP_STRING/.
  * m4/afs.m4 (gl_AFS): Likewise.
  * m4/gc-random.m4 (gl_GC_RANDOM): Likewise.
  * m4/absolute-header.m4 (gl_ABSOLUTE_HEADER): s/AC_FOREACH/m4_foreach_w/.
  * m4/stdint.m4 (gl_STDINT_BITSIZEOF, gl_CHECK_TYPES_SIGNED)
  (gl_INTEGER_TYPE_SUFFIX): Likewise.
  * m4/onceonly_2_57.m4 (AC_CHECK_HEADERS_ONCE, AC_CHECK_FUNCS_ONCE)
  (AC_CHECK_DECLS_ONCE): Likewise.
  Rename file...
  * m4/onceonly.m4: ...to this, and delete 2.54 variant, now that
  gnulib-tool requires autoconf 2.59 or better.
  * gnulib-tool (func_get_filelist): s/\(onceonly\)_2_57.m4/\1.m4/.
  
  Signed-off-by: Eric Blake <ebb9@byu.net>
  

Download

• m4/gc-random.m4

• # gc-random.m4 serial 3
  dnl Copyright (C) 2005-2008 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  AC_DEFUN([gl_GC_RANDOM],
  [
    # Devices with randomness.
    # FIXME: Are these the best defaults?
  
    AC_REQUIRE([AC_CANONICAL_HOST])dnl
  
    case "$host_os" in
      *openbsd*)
        NAME_OF_RANDOM_DEVICE="/dev/srandom"
        NAME_OF_PSEUDO_RANDOM_DEVICE="/dev/prandom"
        NAME_OF_NONCE_DEVICE="/dev/urandom"
        ;;
  
      *netbsd*)
        NAME_OF_RANDOM_DEVICE="/dev/srandom"
        NAME_OF_PSEUDO_RANDOM_DEVICE="/dev/urandom"
        NAME_OF_NONCE_DEVICE="/dev/urandom"
        ;;
  
      *solaris* | *irix* | *dec-osf* )
        NAME_OF_RANDOM_DEVICE="/dev/random"
        NAME_OF_PSEUDO_RANDOM_DEVICE="/dev/random"
        NAME_OF_NONCE_DEVICE="/dev/random"
        ;;
  
      *)
        NAME_OF_RANDOM_DEVICE="/dev/random"
        NAME_OF_PSEUDO_RANDOM_DEVICE="/dev/urandom"
        NAME_OF_NONCE_DEVICE="/dev/urandom"
        ;;
    esac
  
    AC_MSG_CHECKING([device with (strong) random data...])
    AC_ARG_ENABLE(random-device,
  	AS_HELP_STRING([--enable-random-device],
  		[device with (strong) randomness (for Nettle)]),
  	NAME_OF_RANDOM_DEVICE=$enableval)
    AC_MSG_RESULT($NAME_OF_RANDOM_DEVICE)
  
    AC_MSG_CHECKING([device with pseudo random data...])
    AC_ARG_ENABLE(pseudo-random-device,
  	AS_HELP_STRING([--enable-pseudo-random-device],
  		[device with pseudo randomness (for Nettle)]),
  	NAME_OF_PSEUDO_RANDOM_DEVICE=$enableval)
    AC_MSG_RESULT($NAME_OF_PSEUDO_RANDOM_DEVICE)
  
    AC_MSG_CHECKING([device with unpredictable data for nonces...])
    AC_ARG_ENABLE(nonce-device,
  	AS_HELP_STRING([--enable-nonce-device],
  		[device with unpredictable nonces (for Nettle)]),
  	NAME_OF_NONCE_DEVICE=$enableval)
    AC_MSG_RESULT($NAME_OF_NONCE_DEVICE)
  
    if test "$cross_compiling" != yes; then
      if test "$NAME_OF_RANDOM_DEVICE" != "no"; then
        AC_CHECK_FILE($NAME_OF_RANDOM_DEVICE,,
          AC_MSG_WARN([[Device `$NAME_OF_RANDOM_DEVICE' does not exist, consider to use --enable-random-device]]))
      fi
      if test "$NAME_OF_PSEUDO_RANDOM_DEVICE" != "no"; then
        AC_CHECK_FILE($NAME_OF_PSEUDO_RANDOM_DEVICE,,
          AC_MSG_WARN([[Device `$NAME_OF_PSEUDO_RANDOM_DEVICE' does not exist, consider to use --enable-pseudo-random-device]]))
      fi
      if test "$NAME_OF_NONCE_DEVICE" != "no"; then
        AC_CHECK_FILE($NAME_OF_NONCE_DEVICE,,
          AC_MSG_WARN([[Device `$NAME_OF_NONCE_DEVICE' does not exist, consider to use --enable-nonce-device]]))
      fi
    else
      AC_MSG_NOTICE([[Cross compiling, assuming random devices exists on the target host...]])
    fi
  
    # FIXME?: Open+read 42 bytes+close twice and compare data.  Should differ.
  
    AC_DEFINE_UNQUOTED(NAME_OF_RANDOM_DEVICE, "$NAME_OF_RANDOM_DEVICE",
                     [defined to the name of the (strong) random device])
    AC_DEFINE_UNQUOTED(NAME_OF_PSEUDO_RANDOM_DEVICE,
  			 "$NAME_OF_PSEUDO_RANDOM_DEVICE",
                     [defined to the name of the pseudo random device])
    AC_DEFINE_UNQUOTED(NAME_OF_NONCE_DEVICE, "$NAME_OF_NONCE_DEVICE",
                     [defined to the name of the unpredictable nonce device])
  ])
  

Download