kc3-lang/gnulib/m4/mbswidth.m4

• Show log

  Commit

• Hash : 96f7b7d9
  Author :
  Date : 2007-01-16T16:31:23
  

  * modules/fnmatch (Depends-on): Depend on wchar.
  * lib/fnmatch.c (WIDE_CHAR_SUPPORT): Assume <wchar.h>.
  * m4/fnmatch.m4: Likewise.
  * modules/mbchar (Makefile.am): Assume <wchar.h>.
  * m4/mbchar.m4: Likewise.
  * modules/mbswidth (Depends-on): Depend on wchar.
  * lib/mbswidth.c: Assume <wchar.h>.
  * m4/mbswidth.m4: Likewise.
  * modules/quotearg (Depends-on): Depend on wchar.
  * lib/quotearg.c: Assume <wchar.h>.
  * m4/quotearg.m4: Likewise.
  * modules/regex (Depends-on): Depend on wchar.
  * lib/regex_internal.h: Assume <wchar.h>.
  * m4/regex.m4: Likewise.
  * modules/stdint (Depends-on): Depend on wchar.
  * lib/stdint_.h [!defined WCHAR_MIN]: Assume <wchar.h>.
  * m4/stdint.m4: Likewise.
  * tests/test-stdint.c [HAVE_WINT_T]: Likewise.
  * modules/strftime (Depends-on): Depend on wchar.
  * lib/strftime.c (DO_MULTIBYTE): Assume <wchar.h>.
  * modules/strtol (Depends-on): Depend on wchar.
  * lib/strtol.c: Assume <wchar.h>.
  * modules/wcwidth (Depends-on): Depend on wchar.
  * lib/wcwidth.h: Assume <wchar.h>.
  * m4/wcwidth.m4: Likewise.
  

Download

• m4/mbswidth.m4

• # mbswidth.m4 serial 14
  dnl Copyright (C) 2000-2002, 2004, 2006, 2007 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  dnl autoconf tests required for use of mbswidth.c
  dnl From Bruno Haible.
  
  AC_DEFUN([gl_MBSWIDTH],
  [
    AC_CHECK_HEADERS_ONCE([wchar.h])
    AC_CHECK_FUNCS_ONCE([isascii mbsinit])
    gl_FUNC_MBRTOWC
  
    dnl UnixWare 7.1.1 <wchar.h> has a declaration of a function mbswidth()
    dnl that clashes with ours.
    AC_CACHE_CHECK([whether mbswidth is declared in <wchar.h>],
      ac_cv_have_decl_mbswidth,
      [AC_TRY_COMPILE([
  /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
     <wchar.h>.
     BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be included
     before <wchar.h>.  */
  #include <stddef.h>
  #include <stdio.h>
  #include <time.h>
  #include <wchar.h>
  ], [
    char *p = (char *) mbswidth;
    return !p;
  ], ac_cv_have_decl_mbswidth=yes, ac_cv_have_decl_mbswidth=no)])
    if test $ac_cv_have_decl_mbswidth = yes; then
      ac_val=1
    else
      ac_val=0
    fi
    AC_DEFINE_UNQUOTED(HAVE_DECL_MBSWIDTH_IN_WCHAR_H, $ac_val,
      [Define to 1 if you have a declaration of mbswidth() in <wchar.h>, and to 0 otherwise.])
  
    AC_TYPE_MBSTATE_T
  ])
  

Download