kc3-lang/gnulib/m4/readutmp.m4

• Show log

  Commit

• Hash : f76a70dc
  Author :
  Date : 2011-09-15T00:23:57
  

  Properly quote AC_CHECK_DECLS' 4th argument.
  
  * m4/c-stack.m4 (gl_PREREQ_C_STACK): Double-quote AC_CHECK_DECLS' 4th
  argument.
  * m4/ceilf.m4 (gl_FUNC_CEILF): Likewise.
  * m4/ceill.m4 (gl_FUNC_CEILL): Likewise.
  * m4/dirfd.m4 (gl_FUNC_DIRFD): Likewise.
  * m4/floorf.m4 (gl_FUNC_FLOORF): Likewise.
  * m4/floorl.m4 (gl_FUNC_FLOORL): Likewise.
  * m4/fnmatch.m4 (gl_PREREQ_FNMATCH): Likewise.
  * m4/getaddrinfo.m4 (gl_PREREQ_GETADDRINFO): Likewise.
  * m4/getdomainname.m4 (gl_FUNC_GETDOMAINNAME): Likewise.
  * m4/gethrxtime.m4 (gl_GETHRXTIME): Likewise.
  * m4/getpass.m4 (gl_PREREQ_GETPASS): Likewise.
  * m4/inet_ntop.m4 (gl_FUNC_INET_NTOP): Likewise.
  * m4/inet_pton.m4 (gl_FUNC_INET_PTON): Likewise.
  * m4/isfinite.m4 (gl_ISFINITE): Likewise.
  * m4/isinf.m4 (gl_ISINF): Likewise.
  * m4/logb.m4 (gl_FUNC_LOGB): Likewise.
  * m4/readutmp.m4 (gl_READUTMP): Likewise.
  * m4/regex.m4 (gl_PREREQ_REGEX): Likewise.
  * m4/round.m4 (gl_FUNC_ROUND): Likewise.
  * m4/roundf.m4 (gl_FUNC_ROUNDF): Likewise.
  * m4/roundl.m4 (gl_FUNC_ROUNDL): Likewise.
  * m4/signbit.m4 (gl_SIGNBIT): Likewise.
  * m4/sleep.m4 (gl_FUNC_SLEEP): Likewise.
  * m4/strsignal.m4 (gl_PREREQ_STRSIGNAL): Likewise.
  * m4/trunc.m4 (gl_FUNC_TRUNC): Likewise.
  * m4/truncf.m4 (gl_FUNC_TRUNCF): Likewise.
  * m4/truncl.m4 (gl_FUNC_TRUNCL): Likewise.
  * m4/vasnprintf.m4 (gl_PREREQ_VASNPRINTF): Likewise.
  * m4/wctob.m4 (gl_FUNC_WCTOB): Likewise.
  * m4/wcwidth.m4 (gl_FUNC_WCWIDTH): Likewise.
  Reported by Eric Blake.
  

Download

• m4/readutmp.m4

• # readutmp.m4 serial 19
  dnl Copyright (C) 2002-2011 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  AC_DEFUN([gl_READUTMP],
  [
    dnl Persuade utmpx.h to declare utmpxname
    AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  
    AC_CHECK_HEADERS_ONCE([utmp.h utmpx.h])
    if test $ac_cv_header_utmp_h = yes || test $ac_cv_header_utmpx_h = yes; then
      dnl Prerequisites of lib/readutmp.h and lib/readutmp.c.
      AC_REQUIRE([AC_C_INLINE])
      AC_CHECK_FUNCS_ONCE([utmpname utmpxname])
      AC_CHECK_DECLS([getutent],,,[[
  /* <sys/types.h> is a prerequisite of <utmp.h> on FreeBSD 8.0, OpenBSD 4.6.  */
  #include <sys/types.h>
  #ifdef HAVE_UTMP_H
  # include <utmp.h>
  #endif
  ]])
      utmp_includes="\
  AC_INCLUDES_DEFAULT
  #ifdef HAVE_UTMPX_H
  # include <utmpx.h>
  #endif
  #ifdef HAVE_UTMP_H
  # if defined _THREAD_SAFE && defined UTMP_DATA_INIT
     /* When including both utmp.h and utmpx.h on AIX 4.3, with _THREAD_SAFE
        defined, work around the duplicate struct utmp_data declaration.  */
  #  define utmp_data gl_aix_4_3_workaround_utmp_data
  # endif
  # include <utmp.h>
  #endif
  "
      AC_CHECK_MEMBERS([struct utmpx.ut_user],,,[$utmp_includes])
      AC_CHECK_MEMBERS([struct utmp.ut_user],,,[$utmp_includes])
      AC_CHECK_MEMBERS([struct utmpx.ut_name],,,[$utmp_includes])
      AC_CHECK_MEMBERS([struct utmp.ut_name],,,[$utmp_includes])
      AC_CHECK_MEMBERS([struct utmpx.ut_type],,,[$utmp_includes])
      AC_CHECK_MEMBERS([struct utmp.ut_type],,,[$utmp_includes])
      AC_CHECK_MEMBERS([struct utmpx.ut_pid],,,[$utmp_includes])
      AC_CHECK_MEMBERS([struct utmp.ut_pid],,,[$utmp_includes])
      AC_CHECK_MEMBERS([struct utmpx.ut_id],,,[$utmp_includes])
      AC_CHECK_MEMBERS([struct utmp.ut_id],,,[$utmp_includes])
      AC_CHECK_MEMBERS([struct utmpx.ut_exit],,,[$utmp_includes])
      AC_CHECK_MEMBERS([struct utmp.ut_exit],,,[$utmp_includes])
  
      AC_CHECK_MEMBERS([struct utmpx.ut_exit.ut_exit],,,[$utmp_includes])
      AC_CHECK_MEMBERS([struct utmp.ut_exit.ut_exit],,,[$utmp_includes])
      AC_CHECK_MEMBERS([struct utmpx.ut_exit.e_exit],,,[$utmp_includes])
      AC_CHECK_MEMBERS([struct utmp.ut_exit.e_exit],,,[$utmp_includes])
  
      AC_CHECK_MEMBERS([struct utmpx.ut_exit.ut_termination],,,[$utmp_includes])
      AC_CHECK_MEMBERS([struct utmp.ut_exit.ut_termination],,,[$utmp_includes])
      AC_CHECK_MEMBERS([struct utmpx.ut_exit.e_termination],,,[$utmp_includes])
      AC_CHECK_MEMBERS([struct utmp.ut_exit.e_termination],,,[$utmp_includes])
    fi
  ])
  

Download