kc3-lang/gnulib/m4/netinet_in_h.m4

• Show log

  Commit

• Hash : a3fd683d
  Author :
  Date : 2017-01-01T02:59:23
  

  version-etc: new year
  
  * build-aux/gendocs.sh (version):
  * doc/gendocs_template:
  * doc/gendocs_template_min:
  * doc/gnulib.texi:
  * lib/version-etc.c (COPYRIGHT_YEAR):
  Update copyright dates by hand in templates and the like.
  * all files: Run 'make update-copyright'.
  

Download

• m4/netinet_in_h.m4

• # netinet_in_h.m4 serial 5
  dnl Copyright (C) 2006-2017 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  AC_DEFUN([gl_HEADER_NETINET_IN],
  [
    AC_CACHE_CHECK([whether <netinet/in.h> is self-contained],
      [gl_cv_header_netinet_in_h_selfcontained],
      [
        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[]])],
          [gl_cv_header_netinet_in_h_selfcontained=yes],
          [gl_cv_header_netinet_in_h_selfcontained=no])
      ])
    if test $gl_cv_header_netinet_in_h_selfcontained = yes; then
      NETINET_IN_H=''
    else
      NETINET_IN_H='netinet/in.h'
      AC_CHECK_HEADERS([netinet/in.h])
      gl_CHECK_NEXT_HEADERS([netinet/in.h])
      if test $ac_cv_header_netinet_in_h = yes; then
        HAVE_NETINET_IN_H=1
      else
        HAVE_NETINET_IN_H=0
      fi
      AC_SUBST([HAVE_NETINET_IN_H])
    fi
    AC_SUBST([NETINET_IN_H])
    AM_CONDITIONAL([GL_GENERATE_NETINET_IN_H], [test -n "$NETINET_IN_H"])
  ])
  

Download