kc3-lang/gnulib/m4/unlinkdir.m4

• Show log

  Commit

• Hash : 42d1eda5
  Author :
  Date : 2009-01-13T08:48:48
  

  many *.m4 files: improve m4 quoting
  
  99% of this change was performed by running the following commands:
  git ls-files | grep '\.m4$' | xargs perl -pi \
    -e 's/(AC_\w+\()([^[()]+?)([,)])/$1\[$2]$3/g;' \
    -e 's/(AC_\w+\((?:\[[^,]+?\], ){1})([^,[()]+?)([,)])/$1\[$2]$3/g;' \
    -e 's/(AC_\w+\((?:\[[^,]+?\], ){2})([^,[()]+?)([,)])/$1\[$2]$3/g;' \
    -e 's/(AC_\w+\((?:\[[^,]+?\], ){3})([^,[()]+?)([,)])/$1\[$2]$3/g'
  perl -pi -e 's/\[\.\.\.\]/.../' m4/onceonly.m4
  
  The remainder were to add Copyright dates, increment serial numbers,
  undo some changes in comments, exclude m4/intl.m4, and add quotes
  around the "1" in ",1" where the unusual spacing prohibited the
  above regexps from doing the job.  For more details, see
  <http://thread.gmane.org/gmane.comp.lib.gnulib.bugs/16175>.
  

Download

• m4/unlinkdir.m4

• # serial 6
  
  # Copyright (C) 2005, 2006, 2007, 2009 Free Software Foundation, Inc.
  #
  # This file is free software; the Free Software Foundation
  # gives unlimited permission to copy and/or distribute it,
  # with or without modifications, as long as this notice is preserved.
  
  # Written by Paul Eggert.
  
  AC_DEFUN([gl_UNLINKDIR],
  [
    AC_REQUIRE([AC_CANONICAL_HOST])
    AC_CHECK_HEADERS_ONCE([priv.h])
  
    AC_LIBOBJ([unlinkdir])
  
    # The Hurd, the Linux kernel, the FreeBSD kernel version 2.2 and later,
    # and Cygwin never let anyone (even root) unlink directories.
    # If anyone knows of another system for which unlink can never
    # remove a directory, please report it to <bug-coreutils@gnu.org>.
    # Unfortunately this is difficult to test for, since it requires root access
    # and might create garbage in the file system,
    # so the code below simply relies on the kernel name and version number.
    case $host in
    *-*-gnu[[0-9]]* | \
    *-*-linux-* | *-*-linux | \
    *-*-freebsd2.2* | *-*-freebsd[[3-9]]* | *-*-freebsd[[1-9]][[0-9]]* | \
    *-cygwin)
      AC_DEFINE([UNLINK_CANNOT_UNLINK_DIR], [1],
        [Define to 1 if unlink (dir) cannot possibly succeed.]);;
    esac
  ])
  

Download