kc3-lang/gnulib/m4/time_r.m4

• Show log

  Commit

• Hash : 30dccb61
  Author :
  Date : 2009-09-10T20:54:34
  

  Remove obsolete macros from several modules.
  
  * m4/c-stack.m4 (AC_SYS_XSI_STACK_OVERFLOW_HEURISTIC): Replace
  obsolete Autoconf macros with their modern counterparts.
  * m4/check-math-lib.m4 (gl_CHECK_MATH_LIB): Likewise.
  * m4/gc-camellia.m4 (gl_GC_CAMELLIA): Likewise.
  * m4/getaddrinfo.m4 (gl_GETADDRINFO): Likewise.
  * m4/getdate.m4 (gl_C_COMPOUND_LITERALS): Likewise.
  * m4/gethostname.m4 (gl_FUNC_GETHOSTNAME): Likewise.
  * m4/getline.m4 (gl_FUNC_GETLINE): Likewise.
  * m4/getopt.m4 (gl_GETOPT_CHECK_HEADERS): Likewise.
  * m4/isfinite.m4 (gl_ISFINITEL_WORKS): Likewise.
  * m4/poll.m4 (gl_FUNC_POLL): Likewise.
  * m4/readline.m4 (gl_FUNC_READLINE): Likewise.
  * m4/round.m4 (gl_FUNC_ROUND): Likewise.
  * m4/roundf.m4 (gl_FUNC_ROUNDF): Likewise.
  * m4/select.m4 (gl_FUNC_SELECT): Likewise.
  * m4/sockets.m4 (gl_SOCKETS): Likewise.
  * m4/socklen.m4 (gl_TYPE_SOCKLEN_T): Likewise.
  * m4/sockpfaf.m4 (gl_SOCKET_FAMILIES): Likewise.
  * m4/sysexits.m4 (gl_SYSEXITS): Likewise.
  * m4/time_r.m4 (gl_TIME_R): Likewise.
  * m4/tsearch.m4 (gl_FUNC_TSEARCH): Likewise.
  * m4/vararrays.m4 (AC_C_VARARRAYS): Likewise.
  * m4/wctype.m4 (gl_WCTYPE_H): Likewise.
  
  Signed-off-by: Ralf Wildenhues <Ralf.Wildenhues@gmx.de>
  

Download

• m4/time_r.m4

• dnl Reentrant time functions like localtime_r.
  
  dnl Copyright (C) 2003, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  dnl Written by Paul Eggert.
  
  AC_DEFUN([gl_TIME_R],
  [
   dnl Persuade glibc and Solaris <time.h> to declare localtime_r.
    AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  
    AC_REQUIRE([gl_HEADER_TIME_H_DEFAULTS])
    AC_REQUIRE([AC_C_RESTRICT])
  
    AC_CACHE_CHECK([whether localtime_r is compatible with its POSIX signature],
      [gl_cv_time_r_posix],
      [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
           [[#include <time.h>]],
           [[/* We don't need to append 'restrict's to the argument types,
                even though the POSIX signature has the 'restrict's,
                since C99 says they can't affect type compatibility.  */
             struct tm * (*ptr) (time_t const *, struct tm *) = localtime_r;
             if (ptr) return 0;
             /* Check the return type is a pointer.  On HP-UX 10 it is 'int'.  */
             *localtime_r (0, 0);]])],
         [gl_cv_time_r_posix=yes],
         [gl_cv_time_r_posix=no])])
    if test $gl_cv_time_r_posix = yes; then
      REPLACE_LOCALTIME_R=0
    else
      REPLACE_LOCALTIME_R=1
      AC_LIBOBJ([time_r])
      gl_PREREQ_TIME_R
    fi
  ])
  
  # Prerequisites of lib/time_r.c.
  AC_DEFUN([gl_PREREQ_TIME_R], [
    :
  ])
  

Download