kc3-lang/gnulib/m4/utimens.m4

• Show log

  Commit

• Hash : 0883405c
  Author :
  Date : 2009-11-18T06:59:44
  

  utimens: fix regression on Solaris
  
  Revert commit 26c5fd742f.  Solaris lacks futimens and futimes, so
  futimesat is the only way to change fd timestamps.  But since
  FreeBSD futimesat can't change fd timestamps, we need a configure
  check to avoid the crash there.
  
  * m4/utimens.m4 (gl_UTIMENS): Check for BSD bug.
  * lib/utimens.c (fdutimens): Revert 2009-11-08 change; Solaris 10
  can only change fd timestamps via futimesat.  Instead, use an
  additional witness macro to avoid BSD bug.
  Reported by Jim Meyering.
  
  Signed-off-by: Eric Blake <ebb9@byu.net>
  

Download

• m4/utimens.m4

• dnl Copyright (C) 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free
  dnl Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
  dnl with or without modifications, as long as this notice is preserved.
  
  dnl serial 4
  
  AC_DEFUN([gl_UTIMENS],
  [
    AC_LIBOBJ([utimens])
  
    dnl Prerequisites of lib/utimens.c.
    AC_REQUIRE([gl_FUNC_UTIMES])
    AC_REQUIRE([gl_CHECK_TYPE_STRUCT_TIMESPEC])
    AC_REQUIRE([gl_CHECK_TYPE_STRUCT_UTIMBUF])
    AC_CHECK_FUNCS_ONCE([futimes futimesat futimens utimensat lutimes])
  
    if test $ac_cv_func_futimens = no && test $ac_cv_func_futimesat = yes; then
      dnl FreeBSD 8.0-rc2 mishandles futimesat(fd,NULL,time).  It is not
      dnl standardized, but Solaris implemented it first and uses it as
      dnl its only means to set fd time.
      AC_CACHE_CHECK([whether futimesat handles NULL file],
        [gl_cv_func_futimesat_works],
        [touch conftest.file
         AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  #include <stddef.h>
  #include <sys/times.h>
  ]], [[    int fd = open ("conftest.file", O_RDWR);
            if (fd < 0) return 1;
            if (futimesat (fd, NULL, NULL)) return 2;
          ]])],
          [gl_cv_func_futimesat_works=yes],
          [gl_cv_func_futimesat_works=no],
          [gl_cv_func_futimesat_works="guessing no"])
        rm -f conftest.file])
      if test "$gl_cv_func_futimesat_works" != yes; then
        AC_DEFINE([FUTIMESAT_NULL_BUG], [1],
          [Define to 1 if futimesat mishandles a NULL file name.])
      fi
    fi
  ])
  

Download